IFDB Spelunking 2 — 11 of 18

Chapter 2 - Objects In Games

A thing is either acquired or unacquired. A thing is usually unacquired.

A thing has a room called origin.

Every turn:

while the player carries an unacquired thing begin;

let Z be a random unacquired thing carried by the player;

now Z is acquired;

now the origin of Z is the location of the player;

end while;

while the player wears an unacquired thing begin;

let Z be a random unacquired thing worn by the player;

now Z is acquired;

now the origin of Z is the location of the player;

end while;

A thing is either safe or unsafe. A thing is usually unsafe. safety line is safe.

A room can be watery. A room is usually not watery.

A thing has some text called hisp. The hisp of a thing is usually "".

A thing has some text called hisdesc. The hisdesc of a thing is usually "".

A thing can be burnable or non-burnable. A thing is usually non-burnable.

A thing can be tiny. A thing is usually not tiny.

An outfit is a kind of thing. An outfit is usually wearable.

[The player must always wear one outfit; if they wear one, they remove their current one first. Silent exchanges take place the first time a game is opened, if it has a dedicated outfit.]

A person can be prudish or easy-going. A person is usually prudish. An animal is usually easy-going. The player is easy-going.

Before wearing an outfit (called foo):

if the player wears an outfit (called blah) begin;

say "(first removing [the blah])";

if a prudish person is visible begin;

try taking off blah;

stop the action;

otherwise;

now the player carries blah;

continue the action;

end if;

end if;

Instead of taking off an outfit in the presence of a prudish person:

if the current game is Take One begin;

say "[co]Not that kind of movie.[/co]";

otherwise;

say "[co][if the current game is Samhain]It might seem like a good time, but given Ed Mueller's deranged imagination, it'd probably just lead to humiliation and a 90s pop-culture reference[otherwise if the current game is Sweet Sixteen]Moving a little fast there. Which is usually the idea, in AIF, but in this case you really don't want to[otherwise]Not that kind of game[run paragraph on][end if].[/co]";

end if;

Instead of taking off an outfit: say "[co][if the current game is Sweet Sixteen]Moving a little fast there. Which is usually the idea, in AIF, but in this case you really don't want to.[otherwise]There are tunnels - well-known, forgiving, tolerably warm - into which you would venture naked, but it'd be foolish to do so on a random dive. (You could just change into a different outfit, though, if you have one.)[end if][/co]"

your caving gear is an outfit. the player wears caving gear. the description of caving gear is "A helmet, plastered with stickers. Three-quarter-length pants with minimal, zippered pockets and lots of flexibility about the hips. Approach shoes, a compromise between the climber's need to wedge a rigid foot into a hold and the hiker's need for stability, traction and comfort. The tank-top requires no such half-measures: freedom of movement and the vanity of showing off wicked upper-back muscles are in perfect accord." Understand "pants" or "shoes" or "approach shoes" or "three-quarter" or "tank top" or "top" or "clothes" or "clothing" or "tank-top" as caving gear.

the hisp of caving gear is "espeleología equipo". Understand "equipo" or "espeleologia" or "espeleologia equipo" as caving gear.

upper back muscles are part of yourself. The description of upper back muscles is "Routinely climbing out of deep, steep holes has left you with the world's prettiest upper back and shoulders, and its ugliest hands."

Instead of pulling upper back muscles: say "You don't know how far you are away from a reputable sports therapist. No thanks."

the hisp of upper back muscles is "músculos superior de la espalda". Understand "upper-back" or "musculos" or "espalda" or "shoulders" or "shoulder" as upper back muscles.

the player wears your caving helmet. Understand "sticker" or "stickers" as caving helmet. The description of caving helmet is "Your helmet is adorned with mementos of past dives, [if the player wears caving helmet]but you can't really see any of them when you're wearing it[otherwise]such as [one of][i]NARRATIVE HAS A POSSE[/i][or][i]postapocalypse cowboy cheesecake[/i][or][i]When Help Collides[/i][or][i]That Belongs In A Trophy Case![/i][or][i]invent[unicode 8734]ry[/i][or][i]SF Speedrun [']02[/i][at random] or [one of]a plain black-and-white oval that reads, simply, MAMMOTH[or][i]PARSE FREE OR DIE[/i][or][i]Do You Even Deadlift The Phone Booth, Bro[/i][or]a completion badge from a Fire/Liquid/Rope ultra-triathlon[or]an tag that officially licenses you to practice Lavori d'Aracne in Washington State[at random][end if][first time].[p]It doesn't have a light on it. Finding your own light sources is kind of a religion among true spelunkers[only]."

The hisp of caving helmet is "casco de espeleología". Understand "casco" or "espeleologia" as caving helmet.

an outfit can be unsoiled or soiled. an outfit is usually unsoiled.

To wardrobe-change (foo - an outfit):

if foo is unsoiled begin;

if the player wears an outfit (called blah) begin;

now the player carries blah;

end if;

now the player wears foo;

now foo is soiled;

end if;

Instead of examining the player when the current game is nongame: say "You are a person of flexible qualities. In the deeps between the games, you tend towards something moderately youthful, with long limbs and muscle development concentrated in the upper back, core and forearms."

Definition: a thing is cleflike if it unlocks something.

Definition: a thing is locklike if something unlocks it.

Does the player mean unlocking a locklike thing with a cleflike thing: it is likely.

Does the player mean locking a locklike thing with a cleflike thing: it is likely.