IFDB Spelunking 2 — 12 of 18

Part 1 - Mountains of Ket

To reset Mountains of Ket:

now the elixir-count is 0;

[TODO:

endgame

The hole disappears

]

A room has some text called helptext. The helptext of a room is usually "I'm as stumped as you."

Check helping when the current game is Ket:

say "[first time][co][/i]Mountains of Ket[i] is a very difficult game, made more difficult here because combat is largely disabled. The simplest approach is probably a walkthrough, such as may be found at http://www.gamesover.com/walkthroughs/Mountains_of_Ket.txt .[/co][only][br]";

say the helptext of the location of the player;

stop the action.

Talpsing is an action applying to nothing. Understand "say talps" or "talps" as talpsing.

Instead of talpsing when the current game is Mountains of Ket, say "Are you talking to yourself[if talps-heard is true][note 134][end if]?";

Instead of talpsing:

if talps-heard is true begin;

say "That doesn't seem to do anything here.";

otherwise;

say "Say what?";

end if;

Poloing is an action applying to nothing. Understand "polo" or "say polo" as poloing.

Instead of poloing when the current game is Mountains of Ket, say "Are you talking to yourself[if the player is in ket-deadend][note 189][end if][if the player carries wand][note 190][end if]?";

Instead of poloing when the current game is Mountains of Ket and the player is in Ket-deadend and the player carries wand:

say "A 4['] hole appears in the wall.";

the hole disappears in 1 turn from now;

change the east exit of Ket-deadend to Ket-chamber;

change the west exit of Ket-chamber to Ket-deadend;

At the time when the hole disappears:

say "The hole disappears[br]";

change the east exit of Ket-deadend to nothing;

A thing has a number called cost. The cost of a thing is usually 0.

mountains of ket is an unentitled game in startroom.

The precis of ket is "[set link 500][bold type]Mountains of Ket[roman type][end link] [note 1]

by R. A. McCormack (1984)[line break]

2/5 stars".

The description of Mountains of Ket is "[bold type]Mountains of Ket[roman type][line break]by R. A. McCormack[line break]Episode 1 of Ket trilogy [note 3][line break]Cave crawl[line break]1984 [note 4][p]**[line break]A decent specimen of the 1980[']s dungeon crawl. The objective is to cross under a mountain range, but collecting treasures gives extra points. Two-word parser with a small vocabulary and no EXAMINE command. Randomized combat that's usually but not always avoidable. Ample opportunity to render the game unwinnable. Consulting the room-based HELP text is essential to solving some puzzles.[br]-- Carl Muckenhoupt[p][bold type]Tags:[roman type] built-in hints (226), dragon (92), rpg (308), sound (176), two-word parser (622)[first time][p][co]World of Spectrum has archived numerous scans of advertisements and reviews, some of which have the sort of dull, stilted praise that I'd expect from this era, while others are actually sort of critical. Apparently two-word parsers and minimal descriptions sucked even in 1984.[paragraph break] Much of the archived material involves pleas from hopelessly stuck players. One claims to have been stuck on it for two years. Still: [i]treasures[/i].[/co][only][p][set link 520][b]Open it up.[/b][end link]"

Rule for listing nondescript items:

if the current game is Mountains of Ket begin;

say "Around us we can see:[br]";

list the contents of the location, with newlines, indented, with extra indentation, giving brief inventory information, not listing concealed items, suppressing all articles, listing marked items only;

otherwise if the current game is Sweet Sixteen;

say "You can also see:[br]";

list the contents of the location, with newlines, indented, with extra indentation, giving brief inventory information, not listing concealed items, suppressing all articles, listing marked items only;

otherwise;

continue the action;

end if;

To say OKwhine:

say "[one of][or][or][note 40][or][or][note 41][or][stopping]";

A thing can be sharp. A thing is usually not sharp.

a trusty sword is a masc sharp thing. The description of trusty sword is "You've seen dozens of these around one dungeon or another: the Trusty brand First Sword line, mass-produced in China and consumed like disposable chopsticks. A straight, double-edged blade about two and a half feet long, with a basic crosspiece hilt. Light enough to be wielded (or at least waved around in an arguably-threatening manner) by someone who didn't put too many points into STR, sharp enough to cause injury. Makes little odds to you: you're a looter, not a fighter.[p]It could plausibly be used to injure or threaten an unarmed and inexperienced opponent, but will bend, snap and notch if you try to use it in sustained combat, or as a tool."

The hisp of trusty sword is "fiel espada". Understand "fiel" or "espada" as trusty sword.

some coins are a tiny thing.

The hisp of coins is "monedas". Understand "monedas" as coins.

some coins has a number called moneynum. The moneynum of coins is 2.

The description of coins is "[if the current game is not Mountains of Ket]Adventurers of the sword-and-hitpoints sort don't go in much for detail; consequently, the shopkeepers in those regions mill coin like it was going out of style, leaving you with foil-thin, featureless discs about the size of a shirt-button. They [i]are[/i] gold, though. Adventurers are very insistent about that part. [end if]You have [moneynum of coins in words] of them."

Instead of attacking something when the current game is Ket:

if the noun is the player begin;

say "[m38]";

otherwise if the noun is big Log;

if the player carries axe begin;

say "[co]The game only accepts CHOP LOG, but I'll give you that one.[/co]";

try cutting big Log;

otherwise;

say "[co]You're on the right track here, but lack an appropriate tool.[/co]";

end if;

otherwise;

say "[co][one of]Oh no no no. You're willing to venture into the combat-oriented tunnels, if you can get away without any prolonged fights. A single decisive blow is one thing; but you're just not cut out for RNGs and hit-points[or]Nope, still not joining the thews-and-chainmail brigade[stopping].[/co]";

end if;

Instead of buying an acquired thing:

say "[co]You've already got your avaricious mitts on it, which is nine-tenths of the law as far as you're concerned.[/co]";

bandname 2;

Instead of buying something fixed in place (called foo): if foo is fixed in place, say "[co]Even if it were for sale, you're not sure how you'd arrange delivery.[/co]"

Instead of buying something (called foo) when the player does not carry coins:

say "[if the current game is Mountains of Ket]But you have no coins[otherwise]You have no money[end if].";

Instead of buying a person:

if the noun is an animal begin;

continue the action;

otherwise;

say "[co]You've done some pretty low things in your time, but never stooped to slave-trading.[/co]";

end if;

Check buying something (called foo):

if the cost of foo is 0 begin;

say "[if the current game is Ket]I don't know what you mean[otherwise]It's not for sale[end if].";

stop the action;

end if;

Check buying something (called foo):

if the cost of foo > the moneynum of coins begin;

let N be a random man in the location;

say "[N] says[br]'You don't have enough money, it costs [the cost of foo] coins'[p]";

stop the action;

end if;

Carry out buying something (called foo):

let N be a random salesman in the location;

say "The [N] says[br]'O.K. [OKwhine]Thats [the cost of foo] coins'[note 194][p]";

now the moneynum of coins is the moneynum of coins - the cost of foo;

if the moneynum of coins is 0 begin;

remove coins from play;

now coins are unsafe;

end if;

now the player carries foo;

The block buying rule is not listed in any rulebook.

Selling is an action applying to one thing. Understand "sell [something]" as selling.

Instead of selling something unacquired: say "[co]That's not yours to sell.[/co]"

Instead of selling something valuable: say "[co]You're not going to fence your loot down [i]here[/i]. You'd get far better prices up on the surface.[/co]";

Instead of selling safety line in the presence of a shopkeeper: say "[co]You don't want to be stuck here. Or to unleash NPCs into the tunnels. Last time that happened it took months to sort it all out.[/co]"

Definition: a thing is priceless if its cost is 0.

Instead of selling something priceless:

if there is a salesman in the location begin;

let X be a random salesman in the location;

say "The [X] says,[br]'I don't want it.'";

otherwise;

say "[if the current game is Ket]Who are you going to sell to?[br][otherwise][co]Apparently nobody here is willing to buy that.[/co][end if]";

end if;

Check selling something:

if there is no salesman in the location begin;

say "Who are you going to sell to?";

stop the action;

end if;

To cashgain (foo - a number):

if the player does not carry coins, now the player carries coins;

now the moneynum of coins is the moneynum of coins + foo;

Carry out selling something (called foo):

let X be the cost of foo;

let Y be X / 2;

let merchant be a random salesman in the location;

say "The [merchant] says[br]'O.K. [OKwhine]Here are [Y] coins'[br]";

cashgain Y;

now foo is unsafe;

now foo is unacquired;

move foo to the location of player;

Carry out opening ket:

reset Mountains of Ket;

say "[co]As you're making your way down the relevant tunnel, you notice one of the chalk symbols that fellow Spelunkers scrawl to warn one another of particular dangers. This is the glyph that signs for 'important unlisted exits.'[/co]";

wait for any key;

clear the screen;

say "MOUNTAINS[br]OF KET[p]THE FIRST OF A 3 PART SERIES[p][b]BY R.A. McCORMACK[/b][p]1983, Incentive Software Ltd[br]PRESS ANY KEY TO CONTINUE";

wait for any key;

clear the screen;

say "Blah blah statistics screen, and then:[p]";

move the player to Ket-Road;

now the player carries trusty sword;

edgarwhine happens in 17 turns from now;

now the player carries some coins;

now the command prompt is "What shall we do?[br]";

The saferoom of Ket is Ket-road.

At the time when edgarwhine happens:

if the current game is Mountains of Ket, say "Edgar[note 96] says[br]'We'll never get to the mountain at this rate!!'";

Rule for concluding ket:

now the command prompt is ">";

follow the conclusory rule;

Rule for escaping ket:

now the command prompt is ">";

follow the escapology rule;

Rule for retreating ket:

now the command prompt is ">";

follow the retreatage rule;

Check examining a thing (called foo):

if the current game is Mountains of Ket and foo is not carried and foo is not worn begin;

say "But you don't have it[first time][note 31][only][first time][if foo is a person][note 30][end if][only]!";

stop the action;

end if;

Check examining a thing (called foo):

if the current game is Mountains of Ket and foo is not map and foo is not coins and foo is not wand and foo is not Gazette and foo is not armour begin;

say "I see nothing special[note 136][br]";

stop the action;

end if;

Ket-Road is a room. "We are on a road with fields on both sides[note 34]. To our east is a village & a wood."

the helptext of Ket-Road is "Try exploring a bit more!"

Instead of going nowhere when the current game is Mountains of Ket, say "I'm afraid we can't go that way[horsehint]."

Ket-fakeroom is west of Ket-Road. "The path through the mountains is to the east of the village not the west!"

Ket-harvestroom is north of Ket-Road. "We are in a field, the crops here have been harvested." Ket-harvestroom is north of Ket-harvestroom. Ket-fakeroom is west of Ket-harvestroom. Ket-harvestroom is east of Ket-harvestroom. The helptext of Ket-harvestroom is "Try exploring a bit more!"

a long Chain is a thing in Ket-harvestroom. The description of chain is "About ten feet of light chain with a clip at either end, suitable for securing a dog."

The hisp of long chain is "cadena larga". Understand "cadena" or "larga" as long chain.

Ket-ploughedfield is south of Ket-Road. "We are in a ploughed field with bushes nearby and a stable to the east."

Talps-heard is a truth-state that varies. Talps-heard is false.

After going south from Ket-Road:

try looking;

if a random chance of 1 in 3 succeeds begin;

say "You hear someone saying 'TALPS'[note 167][p]";

now talps-heard is true;

end if;

Ket-lowbushes is south of Ket-ploughedfield. "We are amongst some low bushes[br]To our east is a wood."

Ket-village is east of Ket-Road. "We are at a crossroads in the village centre. There are buildings all around." The helptext of Ket-village is "Try exploring a bit more!"

Ket-hardware is north of Ket-village. "We are in a small but clean & tidy hardware shop." The helptext of Ket-hardware is "Try exploring a bit more!"

A salesman is a kind of person.

a shopkeeper is a male salesman in Ket-hardware. "Also here is a Man (shopkeeper)". The printed name of shopkeeper is "Man (shopkeeper)". Understand "man" as shopkeeper.

Check taking a thing in the presence of a person (called foo) while the current game is Mountains of Ket:

if foo is not an animal and foo is not the player and foo is not carried and foo is not worn begin;

say "[The foo] says[br]'You can't just take things from here[note 142].'";

stop the action;

end if;

After taking something when the current game is Mountains of Ket: say "O.K.[OKwhine]"

a Lamp is a thing in Ket-hardware. The cost of Lamp is 2. Lamp is unlit. The description of lamp is "Your basic brass hand-lantern."

The hisp of lamp is "linterna". Understand "linterna" as lamp.

Instead of switching on lamp, try burning lamp;

Instead of burning Lamp:

say "O.K.[OKwhine]";

now Lamp is lit;

sharp Axe is a sharp thing in Ket-hardware. The cost of axe is 2. The description of sharp Axe is "A straightforward splitting axe, two-handed. Too cumbersome to be credible as a weapon, unless your opponent moves very slowly and is made of wood."

The hisp of sharp Axe is "hacha afilada". Understand "hacha" and "afilada" as sharp axe. Understand "ax" as axe.

a phial of Potion is a valuable masc thing in Ket-hardware. The cost of potion is 2. The description of potion is "A glass bottle with a familiar rounded shape. The label just says POTION, but from the scarlet colour of the goop inside you can be confident that it's for healing[first time]. Monster-bashers chug these things like protein shakes, but they're super valuable topside. Thank you, healthcare inflation[only]."

The hisp of phial is "frasco de poción". Understand "frasco" or "pocion" or "frasco de pocion" as phial.

The epilogue of phial of potion is "which you stow in the medicine cabinet rather than getting decent insurance"

Instead of drinking phial: say "[co]Nah, this is way too valuable to just swig for the taste. Also they taste terrible.[/co]"

Ket-lane is south of Ket-village. "We are at the south end of a lane, to our west are the stables and on our east is a house."

Ket-stables is west of Ket-lane and east of Ket-ploughedfield. "These are the stables, they smell of manure." The helptext of Ket-stables is "You could form a stable relationship with a Horse[note 166]."

strong Horse is a masc male animal in Ket-stables. The cost of horse is 4.

Horse can be ridden or unridden. Horse is unridden.

The description of Horse is "You're no judge of horseflesh, but this is a magnificent creature: a mass of jet-black muscle [if horse is ridden]that makes the ground seem very far away[otherwise]towering over you[end if], a springy, precise dressage gait, and a mane and tail considerably swooshier than strictly necessary. You'd like to count him as a treasure, but seriously, you wouldn't believe how difficult it is to sell thoroughbreds without the proper paperwork."

The hisdesc of horse is "El caballo se ve muy incómodo en el interior del carro."

The hisp of horse is "caballo fuerte". Understand "caballo" or "fuerte" as horse.

Rule for writing a paragraph about strong Horse when the location is startroom: say "Gingerly stepping over the uneven cave floor is your strong horse[first time]! You have no idea how he made it all the way from the Ket foothills on his own[only]."

Riding is an action applying to one thing. Understand "ride [something]" as riding. Understand "mount [something]" as riding.

Does the player mean riding strong Horse: it is very likely.

[rule for supplying a missing noun]

Instead of riding something: say "That isn't really something you can ride."

Instead of riding horse when the current game is Mountains of Ket:

if horse is acquired begin;

say "O.K. [OKwhine]";

now horse is ridden;

now the player carries horse;

otherwise;

try taking horse;

end if;

Instead of riding horse:

if horse is unridden begin;

say "[one of]The great black monster must be five and a half feet tall at the shoulder. Now that you're outside Ket, it's a great deal harder to clamber into the saddle, but [horse] is very understanding and eventually you make it[or]You haul yourself inelegantly into the saddle again[stopping].";

otherwise;

say "You're already in the saddle, albeit precariously.";

end if;

now horse is ridden;

now the player carries horse;

Dismounting is an action applying to one thing. Understand "dismount [something]" or "unmount [something]" as dismounting.

Does the player mean dismounting strong Horse: it is very likely.

Instead of dismounting something:

say "You're not riding that. Nor could you, really.";

Stableman is a male salesman in Ket-stables. "Also here is a Stableman".

Understand "man" as stableman.

Instead of taking an unacquired thing (called foo) in Ket-stables:

say "The Stableman says 'You can't just take things from here.'";

Ket-house is east of Ket-lane. Ket-house is south of Ket-eastlane. "The house we are in is very basic, it only has one floor."

owner is a man in Ket-house. The printed name of owner is "a Man (The owner)". Understand "man" as the owner.

Ket-eastlane is east of Ket-village. Ket-eastlane is north of Ket-house. The description of Ket-eastlane is "This lane we are in leads east/west, there is a posh house to the north."

The helptext of Ket-eastlane is "Don't just kill everyone!"

Instead of going north in Ket-house: say "I'm afraid we can't go that way[note 199]." [YES THIS IS ACTUALLY RIGHT]

The helptext of Ket-house is "Don't just kill everyone!"

Ket-poshhouse is north of Ket-eastlane. The description of Ket-poshhouse is "This house is well kept and has two floors."

The helptext of Ket-poshhouse is "Don't just kill everyone[note 170]!"

a Cartographer is a person in Ket-poshhouse. Cartographer can be frosty or toasty. Cartographer is frosty. The initial appearance of Cartographer is "Also here is a Cartographer[br][if the cartographer is frosty]The Cartographer says[br]'Gosh it's cold'.[end if]"

Ket-openfield is east of Ket-eastlane. "We are in an open field, the village lies to our west and a small path leads south." Ket-openfield is east of Ket-openfield.

Instead of going east in Ket-openfield when the horse is ridden:

move the player to Ket-lowvalley;

Ket-smallfield is north of Ket-openfield. "We are in a small field. To our South is a large field."

Ket-nspath is south of Ket-openfield. "We are on a north/south path." The helptext of Ket-nspath is "Try exploring a bit more!"

Ket-riverbank is south of Ket-nspath. "We are standing on a river bank. There is a wood to our west and a small path leads north." Ket-riverbank is watery.

Ket-woods is south of Ket-lane, east of Ket-lowbushes and west of Ket-riverbank. "The wind is blowing through the trees of the wood we are now in. There is a path going east and the sound of voices comes from the north."

The helptext of Ket-woods is "Don't just kill everyone[note 168]!"

A big Log is a burnable thing in Ket-woods. The description of log is "What rolls down stairs, alone or in pairs, rolls over your neighbour's dog? oh GOD DAMMIT, you're going to be earwormed all day now."

Instead of cutting big Log:

if the player carries axe begin;

if the player carries big Log begin;

say "What? While you're carrying it";

otherwise;

remove big Log from play;

say "[br]chop! chop! Its done.";

move chopped logs to the location of player;

now big Log is not safe;

end if;

otherwise;

say "What with (Your hands)?[note 42][br]";

end if;

Chopped Logs is a burnable thing. The description of Chopped Logs is "Well, it's more like kindling, really. You're not burly enough to chop wood against the grain."

Instead of giving Chopped Logs to the Cartographer:

say "The Cartographer says[br]'O.K. [OKwhine]Here are 7 coins and you can have my MAP too.'";

now cartographer is toasty;

cashgain 7;

now chopped logs are in Ket-poshhouse;

now chopped logs are not safe;

now the player carries the old map;

Instead of giving something to the Cartographer:

say "The Cartographer says[br]'I don't want it[if the noun is big log][note 171][end if].'";

an old Map is a masc burnable thing. The description of old Map is "It shows the path through the mountains to be EAST of some boulders[note 32]."

The hisp of old map is "viejo mapa". Understand "viejo" or "mapa" as old map.

Ket-lowvalley is a room. The description of Ket-lowvalley is "We are in a low valley, the grass here is burnt."

The helptext of Ket-lowvalley is "Try exploring a bit more!"

Instead of going west in Ket-lowvalley when the horse is ridden:

move the player to Ket-openfield;

Ket-northvalley is north of Ket-lowvalley. The description of Ket-northvalley is "We are at the north end of the Valley, it is blocked by rocks". The helptext of Ket-northvalley is "Try exploring a bit more!"

Ket-bleakfield is south of Ket-lowvalley. The description of Ket-bleakfield is "We are in a bleak field. There are other fields all around." The helptext of Ket-bleakfield is "Try exploring a bit more!"

Ket-barrens is south of Ket-bleakfield. "The land around us is barren." The helptext of Ket-barrens is "Try exploring a bit more!"

Ket-spoiltfield is west of Ket-bleakfield. "We are in a spoilt field." The helptext of Ket-spoiltfield is "Try exploring a bit more!"

Ket-boulderfield is east of Ket-bleakfield. "We can see a field in the west around us are boulders." The helptext of Ket-boulderfield is "Try exploring a bit more!"

Ket-cliffface is east of Ket-lowvalley. "We are at the base of a sheer and crumbling cliff face."

a pair of Dice are a tiny thing in Ket-cliffface. The description of pair of dice is "They're wargaming-sized, a sort of yellowish-white with black pips, and quite light. Possibly made out of bone."

pair of dice are masc.

The hisp of dice is "par de dados". Understand "dados" or "par" or "par de dados" as dice.

old map can be unexamined or examined. old map is unexamined.

Carry out examining old map: now old map is examined.

Instead of going east in Ket-boulderfield when old map is unexamined:

say "I'm afraid we can't go that way[horsehint].";

Ket-caveentrance is east of Ket-boulderfield. "To our south is the mountain, with a cave entrance in its base".

a false Beard is in Ket-caveentrance. The description of false Beard is "A mass of hair with a couple of earhooks. On closer inspection, it seems to be made of the pelts of several small, furry animals."

The hisp of beard is "barba postiza". Understand "barba" or "postiza" as beard. false beard is wearable.

Instead of going south in Ket-caveentrance when the player carries the horse:

say "The HORSE will not enter[note 33]!";

Instead of going south in Ket-caveentrance:

say "As you entered the cave a huge gate slammed down behind you. You are trapped in the mountain until you can find another way out!";

move horse to startroom;

now horse is safe;

wait for any key;

move the player to Ket-cave1;

Rule for printing the description of a dark room when the current game is Mountains of Ket: say "Gasp! Its too dark to see!"

Instead of dismounting horse:

say "You clamber from Strong Horse's back. It feels a lot safer to be on the ground.";

now horse is unridden;

now horse is in the location of player;

Instead of dismounting horse when the current game is Mountains of Ket:

say "O.K. [OKwhine][br]";

now horse is unridden;

now horse is in the location of player;

Does the player mean dismounting the horse: it is very likely.

Does the player mean riding the horse: it is very likely.

Ket-caves is a region.

A room can be patrolled. A room is usually not patrolled.

Ket-cave1 is a room. Ket-cave1 is in Ket-caves. Ket-cave1 is dark. The description of Ket-cave1 is "We are in a cave. In its centre is a column of stone. There are entrances all around but the way North is blocked by a Gate". The helptext of Ket-cave1 is "This may be a good place to leave things[note 174]." Ket-cave1 is patrolled.

a pile of Gems is in Ket-cave1. pile of Gems is valuable. The description of gems is "Whenever something is measured by the pile, there's good grounds to doubt that it's hugely valuable. And indeed, looking closer at this pile, it's mostly tumbled semiprecious pebbles - tiger-eyes, turquoises and agates, the sort of thing you'd see piled up in bins at a gift-shop. There are some decent fire opals in there, though, and a scattering of tiny emeralds."

The hisp of gems is "pila de piedras". Understand "pila" or "piedras" or "pila de piedras" as gems.

The epilogue of pile of Gems is "which make an infinitesimal dent in your college loans"

Ket-guardroom is west of Ket-cave1. It is dark. Ket-guardroom is in Ket-caves. "This is the guard room. It smells of unwashed bodies." The helptext of Ket-guardroom is "Try exploring a bit more!"

A thing can be dog-et. A thing is normally not dog-et.

some tasty Food is in Ket-guardroom. The description of tasty food is "An unmarked Mason jar of home-canned... something. Brown greasy chunks in pondwater. It's not the idea of eating potted beholder or umber hulk that gets to you so much; it's that you really don't trust adventurers to follow proper anti-botulism practice, which is hard to accomplish in a dungeon." Ket-guardroom is patrolled.

The hisp of tasty food is "sabrosa comida". Understand "sabrosa" or "comida" or "conserva" or "lata" as tasty food.

tasty food is dog-et.

Instead of eating tasty food when the current game is Ket:

say "Yum! Yum[note 213]!";

remove food from play;

Instead of eating tasty food when the current game is Dracula:

say "¡Mmm! ¡Mmm[note 213]!";

remove food from play;

Instead of eating tasty food:

say "Aside from being cold, rubbery and unspeakably greasy, it's actually really good. [We] can't identify the taste, exactly, and it's probably safer not to speculate.";

remove tasty food from play;

The hisdesc of tasty food is "Una lata de conserva, platija en aceite oliva con granos de pimienta y hojitas de laurel. Se ve delicioso."

Ket-archceiling is east of Ket-cave1. It is dark. Ket-archceiling is in Ket-caves. "The room we are in has a high arched ceiling. A faint breeze comes from the south." Ket-archceiling is patrolled.

Ket-crosspassage is south of Ket-cave1. It is dark. Ket-crosspassage is in Ket-caves. "We are at a cross passage and can see a strange sight[note 35] to the south." Ket-crosspassage is patrolled.

A monster is a kind of person.

A monster has a number called deathnumber.

A monster has some text called deathscript. The deathscript of a monster is usually "You are ripped limb from limb."

the goblin Guard is a monster in Ket-crosspassage.

The deathnumber of goblin Guard is 4.

The deathscript of goblin Guard is "The goblin Guard springs upon you with a gleeful screech, and proceeds to turn you into kebab meat."

An every turn rule (this is the wandering goblin rule):

if the current game is Mountains of Ket and a random chance of 1 in 3 succeeds begin;

if goblin guard is in a room (called the current space) and the player is not in current space begin;

let next space be a random patrolled room which is adjacent to the current space;

move goblin guard to next space;

if player is in next space, say "A GOBLIN GUARD enters the area.";

[TO DO: find what the message is here]

end if;

end if;

The wandering goblin rule is listed after the monster threat rule in the every turn rules.

The attack-count is a number that varies. The attack-count is 0.

After dropping something in Ket-caves:

if the guard dog is not in the location of the player begin;

say "A large RAT grabs it and runs away before you can do a thing[note 92].";

remove the noun from play;

now the noun is not safe;

otherwise;

continue the action;

end if;

Ket-strawroom is a dark room in Ket-caves. It is west of Ket-crosspassage.

Every turn (this is the monster threat rule):

if there is a monster in the location of the player begin;

let Z be a random monster in the location of the player;

now the attack-count is the attack-count + 1;

if the attack-count is 1, say "[co]Don't look now, but [the Z] looks awfully threatening.[/co]";

if the attack-count is 2, say "[co]Look, [the Z] is definitely planning to attack any moment now. You're not prepared to handle an opponent of this calibre. Beat it, kid.[/co]";

if the attack-count is 3 begin;

say "[co][the deathscript of Z][/co]";

let Q be the deathnumber of Z;

deathify Q;

carry out the escaping activity with the current game;

end if;

otherwise;

now the attack-count is 0;

end if;

guard Dog is a masc animal in Ket-strawroom. guard Dog can be friendly, unfriendly or chained. guard Dog is unfriendly.

The description of guard dog is "[if the current game is Dracula]Eine ungeheure schwarze Schäferhund mit einem ständig begeisterten Ausdruck[otherwise]An immense black Alsatian with a perpetually enthusiastic expression[end if]."

The hisp of guard dog is "perro guardián". Understand "perro" or "guardian" as guard dog.

Feeding is an action applying to one thing.

Understand the command "feed" as something new.

Understand "feed [something]" as feeding.

Instead of feeding something:

say "[co]You're just trying to make trouble, aren't you?[/co]";

Instead of feeding a person:

say "[co]Are you [the noun]'s keeper? Don't answer that.[/co]";

Instead of feeding the player:

say "[co]Sadly, there are no abusive dentists to be found.[/co]";

Instead of feeding guard dog:

if the player carries a dog-et thing begin;

let N be a random dog-et thing carried by the player;

try the player giving N to guard dog;

end if;

Instead of giving a dog-et thing to guard dog:

if guard dog is friendly begin;

say "[co]You won't get much guarding out of an overfed guard-dog.[/co]";

otherwise;

say "The dog instantly becomes your friend and wolfs down the food[note 95].";

now guard dog is friendly;

end if;

Instead of taking the guard dog when guard dog is unfriendly: say "He nearly bites your arm off as you near him."

Instead of dropping something in the presence of a person (called foo) when the current game is Mountains of Ket:

if foo is not the player and foo is not an animal begin;

say "The [foo] says[br]'You can't leave things here'[br]";

otherwise;

continue the action;

end if;

chaining is an action applying to one thing. Understand "chain [something]" or "tie [something]" as chaining.

Instead of chaining something: say "You can't do that[note 93]!"

Instead of tying the chain to something: try chaining the second noun.

Instead of tying something to the chain: try chaining the noun.

Instead of chaining the player when the player carries the chain: say "[co][if the current game is Sweet Sixteen]All right, this [i]is[/i] that kind of game, but evidently it's not catering to that specific kink[otherwise]Hey now, this isn't that kind of game[end if].[/co]"

Instead of chaining guard dog when the current game is Mountains of Ket: say "I see nothing to chain him to."

Instead of chaining the guard dog when the current game is Mountains of Ket and the player is in Ket-cave1 and the player carries the chain:

say "You tie the dog to the pillar. He looks fierce enough to guard anything[note 94].";

remove the chain from play;

now the guard dog is chained;

now the guard dog is in Ket-cave1;

[A Dog chained to the column]

Instead of taking guard dog:

if guard dog is chained, say "You can't!";

if guard dog is unfriendly, say "***TODO****";

if guard dog is friendly begin;

say "[if the current game is mountains of ket]O.K[otherwise if the current game is Dracula]Se llama [guard dog] a su lado[note 173][otherwise]You whistle [guard dog] to your side[end if].";

now the player carries guard dog;

end if;

Ket-toilet is a dark room in Ket-caves. It is east of Ket-crosspassage. The description of Ket-toilet is "Obviously this chamber has been used as a toilet[bathe 1][note 91]."

a Wand is a thing in Ket-toilet. The description of wand is "[if the current game is Mountains of Ket]The word MINT is on it[otherwise]It's a foot-long rod with a star on the end. You know, a wand. Back in the [']80s there wasn't much interest in the resonances of particular woods or wand cores or other artisanal concerns; this one is plastic and has a certain air of novelty swizzle-stick.[p]The word MINT is prominently embossed on the shaft[end if]."

The hisp of Wand is "varilla de virtudes[note 153]". Understand "varilla" or "virtudes" or "varilla de virtudes" as wand.

The hisdesc of wand is "Se trata de un pie de largo varilla con una estrella en la punta."

Instead of waving wand when the current game is mountains of ket: say "Nothing Happens!";

Instead of examining wand when the current game is mountains of ket: say "The word 'MINT' is on it.";

Ket-chamber is a dark room in Ket-caves. "We are in a chamber. There is an archway to our south and from the east comes the smell of incense."

A copy of the Goblin Gazette is in Ket-chamber. The description of Gazette is "It tells of an OGRE who just loves to play dice and is very good at it."

The hisp of Gazette is "copia de la Gaceta Trasgo". Understand "copia" or "Gaceta" or "Trasgo" as Gazette.

Understand "post" or "woo-woo" as Gazette when the current game is Samhain.

Understand "copy" or "Magnetism" as Gazette when the current game is Sweet Sixteen.

Understand "copia" or "Blackwood" or "Magazine" as Gazette when the current game is Dracula.

Understand "Screw" or "Bechdel" or "Screw the Bechdel" as Gazette when the current game is Take One.

Understand "copy" or "Protoliterate" or "Times" as Gazette when the current game is ARGH's.

Rule for printing the name of Goblin Gazette:

if the current game is:

-- Samhain: say "copy of the Woo-Woo Post";

-- Sweet Sixteen: say "copy of Magnetism";

-- Dracula: say "copia de la Blackwood Magazine";

-- ARGH's: say "copy of the Protoliterate Times";

-- Take One: say "copy of Screw the Bechdel";

-- otherwise: say "copy of the Goblin Gazette";

Instead of examining the Goblin Gazette:

if the current game is:

-- Mountains of Ket: say "It tells of an OGRE who just loves to play dice and is very good at it.";

-- Samhain: say "This is a magazine about magick for the less discerning practitioner. About three-quarters of it is advertisements for crystals and the like, but there's a featured article about virgin sacrifice. Most of this is an excuse for heavily Photoshopped images of elfy young women on historically questionable altars, but there is a mention of how otherworldly or artificial beings can use sacrifices to become human themselves.";

-- Sweet Sixteen: say "[i]Magnetism[/i], the magazine for the aspiring seduction artist, is about half douchebag training school and half adverts for cologne, penis enhancements and Fleshlights. There are many of pictures of women looking either submissively fascinated or post-orgasmic. One article, entitled [i]Alpha to Alpha[/i], gives advice on how to deal with a possessive and threatening father: [i]'Like the manly wolf, try reaching out to her father over a meal of red meat. He will recognise your status as an assertive leader, and inwardly accept your right to claim his cub.'[/i]";

-- ARGH's: say "A series of bone discs, upon which have been burned a disorderly set of pictographs and simple shapes that might plausibly have signified something to the person who inscribed them. The only pictograph that looks like anything at all... might be a stick-figure bottle-feeding a very fat marmot.";

-- Dracula: say "Thank god, this is in English. You leaf through the formidable journal of poetry and prose, and happen upon a short story about a man who, falling asleep while travelling in a foreign land, is trapped in a seemingly endless labyrinth of unsettling dreams. Eventually -- betrayed, forsworn, dying in extreme privation -- he realises that he never thought to try waking up, and now it is too late and he has forgotten how.";

-- Take One: say "This is the official newsletter of the American Motion Picture Producers' Association, [i]Screw Bechdel![/i] It's about as depressing as you'd expect.";

-- otherwise: say "Goblins crop up in a number of the caves; unlike orcs, their range of variation has never extended to rehabilitation into good-hearted outsiders, and their reading materials are finger-paint scrawls on stolen paper. Generally in some variety of body fluid.";

path-to-archway is a dark room in Ket-caves. path-to-archway is south of Ket-chamber. The description of path-to-archway is "Up ahead we can see an archway".

Ket-flightstairs is a dark room in Ket-caves. Ket-flightstairs is south of path-to-archway. The description of Ket-flightstairs is "There are a flight of stairs going up from here. To the west is a chamber and there are holes in the south wall."

a Gremlin is a person in Ket-flightstairs. "Also here is a Gremlin.[p]The Gremlin cowers near the small holes and points in."

[An apparently pointless maze; the only purpose, as far as I can see, is to get you lost.]

Ket-chamber2 is a dark room in Ket-caves. Ket-chamber2 is west of Ket-flightstairs. The description of Ket-chamber2 is "This chamber has a thin layer of dust on its floor."

Ket-tinytunnels is a dark room in Ket-caves. The description of Ket-tinytunnels is "We enter some tiny tunnels." Ket-tinytunnels is south of Ket-flightstairs. Ket-tinytunnels is north of Ket-tinytunnels.

Ket-lowtunnels is a dark room in Ket-caves. "We enter some low tunnels."

Ket-smallwinding is a dark room in Ket-caves. "We enter some small winding tunnels."

Ket-tunnel is a dark room in Ket-caves. "We enter some small tunnels."

Ket-tinytunnels is north of Ket-tinytunnels.

Ket-smallwinding is east of Ket-tinytunnels.

Ket-lowtunnel is south of Ket-tinytunnels.

Ket-tunnel is west of Ket-tinytunnels.

Ket-tinytunnels is up of Ket-tinytunnels.

Ket-smallwinding is down of Ket-tinytunnels.

Ket-lowtunnels is north of Ket-lowtunnels.

Ket-tunnel is east of Ket-lowtunnels.

Ket-tinytunnels is south of Ket-lowtunnels.

Ket-smallwinding is west of Ket-lowtunnels.

Ket-tunnel is down of Ket-lowtunnels.

Ket-tunnel is north of Ket-tunnel.

Ket-tinytunnels is east of Ket-tunnel.

Ket-smallwinding is south of Ket-tunnel.

Ket-lowtunnels is west of Ket-tunnel.

Ket-tunnel is up of Ket-tunnel.

Ket-tinytunnels is down of Ket-tunnel.

Ket-smallwinding is north of Ket-smallwinding.

Ket-lowtunnel is east of Ket-smallwinding.

Ket-tunnel is south of Ket-smallwinding.

Ket-tinytunnels is west of Ket-smallwinding.

Ket-smallwinding is up of Ket-smallwinding.

Ket-tunnel is down of Ket-smallwinding.

Instead of going up in Ket-lowtunnels:

move the player to Ket-flightstairs;

say "[co]Gods and monsters, but that was a great deal of nonsense. You feel a certain bloody-minded satisfaction for getting out of there without resorting to the safety line, at least.[/co]";

accomplish accomp6;

Before going south in Ket-flightstairs:

if accomp6 is activated begin;

say "[co]Oh no. You're not putting up with that bullshit again, no matter how nicely you've mapped it.[/co]";

stop the action;

end if;

Pretty Necklace is a valuable masc thing in Ket-chamber2. The description of Pretty Necklace is "[co]Every link of it is a different gaudy colour of gem; it's the sort of thing that a six-year-old in a princess phase might adore. You'd expect it to be made of cheap plastic, not several hundred grain jewels set in sterling silver.[/co]".

The hisp of necklace is "bonito collar". Understand "bonito" or "collar" as necklace.

The epilogue of pretty necklace is "which you barter on Etsy for some chainmail gloves"

Ket-warmroom is a dark room in Ket-caves. Ket-warmroom is up from Ket-flightstairs. The description of Ket-warmroom is "We are in a warm room with a shut door to the west. In the south is a ramp leading down to a den."

dragon-count is a number that varies. dragon-count is 0.

Before going up in Ket-flightstairs:

now dragon-count is 0;

a ramp is scenery in Ket-warmroom. ramp can be oily or unoiled. ramp is unoiled.

Instead of pouring bottle of oil in Ket-warmroom:

say "You pour the oil on the ramp making It very slippery.[br]The bottle is now EMPTY.[br]";

remove bottle of oil from play;

now bottle of oil is not safe;

now player carries empty bottle;

now ramp is oily;

Every turn when the player is in Ket-warmroom:

now dragon-count is dragon-count + 1;

if dragon-count is 2 begin;

if ramp is unoiled begin;

say "A [b]HUGE DRAGON[/b] struggles up the ramp into the room.";

wait for any key;

say "[co]Even if you were the surly burly type that usually frequents this place, this fight would be extremely brief. As it is, you're consumed in one bite.[/co]";

deathify 12;

carry out the escaping activity with Mountains of Ket;

otherwise;

say "The [b]HUGE DRAGON[/b] struggles up the ramp but slips back down.";

end if;

end if;

Ket-westside is a room in Ket-caves. "We are on the west side of a door. To our west is a landing."

chamber door is a closed door. chamber door is scenery. chamber door is west of Ket-warmroom and east of Ket-westside.

Check an actor going (this is the replacement can't go through closed doors rule):

if the door gone through is chamber door and the door gone through is closed begin;

say "I'm afraid we can't go that way[note 193].";

stop the action;

otherwise;

abide by the can't go through closed doors rule;

end if;

The replacement can't go through closed doors rule is listed instead of the can't go through closed doors rule in the check going rules.

Instead of opening chamber door:

say "You manage to OPEN the DOOR, but it begins to swing shut.";

the dragongate closes in one turn from now;

now chamber door is open;

At the time when the dragongate closes:

if the player is in Ket-warmroom or player is in Ket-westside begin;

say "The door swings shut.";

end if;

now chamber door is closed;

Ket-landing is west of Ket-westside. "This is a landing. To the north is a sweet smelling chamber some stairs down are also here." Ket-landing is in Ket-caves.

Ket-landing can be checked or unchecked. Ket-landing is unchecked.

Every turn while the player is in Ket-landing: [FIX THIS BIT]

let N be the achieved corresponding to a count of 15 in the Table of Deaths;

if N is true and Ket-landing is unchecked begin;

say "Delphia emerges from her chambers, trailed by her burly ogre. You flinch involuntarily, and she rolls her eyes.[p]'Look, kid, you put on such a pathetic show back there that you're clearly not from around these parts. So I feel obliged to warn you that without my magic luck ring, you'll never past the Guardian Beyond the Skull Gate, which is the only route through the Mountains of Ket.'[p]'Oh.'[p]'I'm hoping we can work something out, though. My understanding is that you are a walker between the worlds?'[p]'More or less.'[p]'Then I suggest a trade. As the only woman in the domain of Ket, I -'[p]'What about the Cartographer? Zie seemed kind of ambiguous.'[p][lady 0]'That's just because you can't enter his combat screen. Anyway, look, I'd like to correspond with the great women of far-off kingdoms, so if you could bring me word.'[p]Delphia heads back towards her room. 'Anyway, hit me up once you've got some news.'";

now Ket-landing is checked;

end if;

The ladylist is a list of numbers that varies. The ladylist is {}.

The done-ladylist is a list of numbers that varies. The done-ladylist is {}.

This is the world-ladies rule:

say "Delphia looks up as you enter. 'So, how's it going? Found any [one of][or]more [stopping]correspondents in the many worlds?'[br]";

if the number of entries in the ladylist is 0 begin;

say "'[one of]Not yet[or]Well, it's difficult territory, y'know? They don't exactly give out a XYZZY for Most Effortlessly Passed Bechdel[or]Afraid not[or]Afraid not. There just aren't that many NPCs in general[or]Not that I could find[at random].'[p]'Well, keep looking. Helmut will show you out[first time]. No offence, you understand; but adventurers have sticky fingers[only].'";

otherwise;

repeat with N running through the ladylist begin;

choose a row with count of N in the Table of Notable Women;

say "[br]";

say the response entry;

[probably some transitions here]

remove N from the ladylist;

add N to the done-ladylist;

end repeat;

if the number of entries in the done-ladylist > 3 begin;

say "Delphia sighs deeply. 'Well, I suppose that beggars can't be choosers, and out of the crooked timber. Thus and thus. No praise, no blame.'[p]'Does that mean I get the ring, or not?'[p]'I feel that you are insufficiently engaged with the purpose of this exercise,' says Delphia, 'but fine, take the stupid luck ring. If you'll excuse me, I should really be taking off now; I have responsibilities in Part 2.'[p]With that, she vanishes in a puff of green smoke. ";

remove Ogre from play;

remove Delphia from play;

now the player carries magic luck ring;

otherwise;

say "[p]'And that's it?'[p]'So far, yes.'[p]'I think that's a pretty poor exchange for a Grade III talisman. Forgive me, but you're going to have to track down some more women. Good day.'[p]The ogre shows you the door, in a manner that does not brook argument.";

end if;

end if;

wait for any key;

if Delphia is in Ket-sweetchamber, move the player to Ket-landing;

Table of Notable Women

Ket-sweetchamber is a room in Ket-caves. It is north of Ket-landing. The description of Ket-sweetchamber is "This chamber is furnished richly and smells of perfume."

A magic luck Ring is a tiny thing in Ket-sweetchamber.

an Ogre2 is a person in Ket-sweetchamber. The printed name of ogre2 is "Ogre".

High Priestess Delphia is a woman in Ket-sweetchamber.

Every turn while the player is in Ket-sweetchamber:

let N be the achieved corresponding to a count of 15 in the Table of Deaths;

if N is false begin;

say "[co]Delphia immediately orders her Ogre to attack you. Ogres are only mid-range as far as bodyguard mooks go, and a real warrior might have prevailed here; you, on the other hand, get crushed like a bug.[/co]";

wait for any key;

deathify 15;

carry out the escaping activity with Mountains of Ket;

otherwise if Delphia is in Ket-sweetchamber;

follow the world-ladies rule;

end if;

Ket-littleused is a dark room in Ket-caves. It is down from Ket-landing. The description of Ket-littleused is "We are in a little used room. There are stairs up and an entrance to the south."

a mages Cloak is an outfit in Ket-littleused.

The hisp of mages cloak is "capa del mago". Understand "capa" or "mago" or "capa del mago" as mages cloak.

The description of mages Cloak is "It's a navy blue with stars and crescent moons on it, true, but it's a bit nicer quality than that makes it sound. Good sturdy material. Small, tasteful star-and-moon print in a spare, regular pattern."

Ket-acrid is a dark room in Ket-caves. "We are in a small chamber, the tunnel entering it from the east has an acrid smell and the light is coming from the south[br]". Ket-acrid is south of Ket-littleused.

Ket-ledge is south of Ket-acrid. "We are on a ledge on the side of a mountain. Hundreds of feet below is a river."

Instead of going south in Ket-ledge:

say "You step off the ledge to meet your death on the rocks below.";

deathify 13;

carry out the escaping activity with Mountains of Ket;

Ket-bigchamber is a dark room in Ket-caves. Ket-bigchamber is east of Ket-acrid. The description of Ket-bigchamber is "We are at the south end of a big chamber. A wide passage leads south."

Every turn when the player is in Ket-bigchamber:

if the player carries jeweled Bracelet begin;

say "You hear a roar and an UGLY but GIANT DRAGON arrives.";

wait for any key;

say "[co]Even if you were the surly burly type that usually frequents this place, this fight would be extremely brief. As it is, you're consumed in one bite.[/co]";

deathify 12;

carry out the escaping activity with Mountains of Ket;

end if;

Ket-dragonsden is a dark room in Ket-caves. "Foolshly we are in the LARGE DRAGONS den." Ket-dragonsden is north of Ket-bigchamber.

jeweled Bracelet is a valuable wearable thing in Ket-dragonsden. The description of jeweled Bracelet is "It's an art-nouveau swirly sort of thing of two dragonflies that are nymphs above the waist, either dancing or moving to embrace one another. There are an awful lot of blue sapphires worked into it."

the epilogue of jeweled bracelet is "which turns out to be worth about two months['] rent on the art black market".

Ket-widepassage is a dark room in Ket-caves. "The wide passage continues. The walls are scorched." Ket-widepassage is south of Ket-bigchamber.

Ket-plateau is south of Ket-widepassage. "We are just outside the passage on a mountain plateau."

Ket-southplat is south of Ket-plateau. "We are on the south edge of the plateau. To our south is a 20' wide crevasse and another plateau."

yourself can be springy. yourself is not springy.

Instead of going south in Ket-southplat:

if the player is springy begin;

say "You spring across the crevasse.";

now the player is in Ket-smallplat;

otherwise;

say "You step off the ledge to meet your death on the rocks below.";

deathify 13;

carry out the escaping activity with Mountains of Ket;

end if;

Ket-smallplat is a room. "You are on the southern plateau, it is very small[note 217]."

Instead of going north in Ket-smallplat:

if the player is springy begin;

say "You spring across the crevasse.";

now the player is in Ket-southplat;

otherwise;

say "You step off the ledge to meet your death on the rocks below.";

deathify 13;

carry out the escaping activity with Mountains of Ket;

end if;

the mages Hat is a masc wearable thing in Ket-smallplat.

the hisp of mages hat is "sombrero de mago". Understand "sombrero" or "mago" or "sombrero de mago" as mages hat.

The description of mages Hat is "A dark blue affair in a familiar cone-and-brim shape."

Ket-antechamber is a dark room in Ket-caves. "This is an ante-chamber that has a religious feel to it. In the south wall is a decorated archway."

Ket-antechamber is east of Ket-chamber.

a Mad Monk is a man in Ket-antechamber.

Every turn when the player is in Ket-antechamber and Mad Monk is in Ket-antechamber:

if the player carries the diamond begin;

say "The Mad Monk says,[br]'You have stolen the sacred diamond, now DIE'[br]";

wait for any key;

if the player carries the magic sword begin;

say "[co]To your surprise, the Monk turns out to be a decidedly feeble opponent, and the magic sword does most of the fighting for you. Afterwards, his corpse vanishes somehow while you're busy throwing up.[/co]";

remove the Mad Monk from play;

accomplish accomp1;

otherwise;

say "[co]Withered by ascetic decades, the Monk is scarcely more formidable than you are. Unfortunately, this just makes the ensuing violence haphazard and brutal.[/co]";

deathify 11;

carry out the escaping activity with Mountains of Ket;

end if;

otherwise;

say "The Mad Monk stares at you[br]";

end if;

Ket-shrine is a room in Ket-caves. "This is the shrine of some god, a pool is in its centre about which you get an odd feeling". Ket-shrine is south of Ket-antechamber.

a large Diamond is a tiny valuable masc thing in Ket-shrine.

The hisp of diamond is "gran diamante". Understand "gran" or "diamante" as diamond.

The description of large Diamond is "It's about the size of a quail's egg. You'd be more excited about this if you hadn't tried to fence diamonds before, but even after everybody's taken their cut, it'll amount a nice little sum."

The epilogue of diamond is "which, without De Beers-certified paperwork, you manage to fence for about the cost of a nice dinner for two".

Ket-orcroom is a dark room in Ket-caves. "The walls of this area shimmer and you get an uneasy feeling." Ket-orcroom is south of Ket-archceiling.

an Orc is a person in Ket-orcroom. orc can be hostile or amiable. orc is hostile.

Every turn when the player is in Ket-orcroom and Orc is hostile:

say "The Orc says[br]'What is the PASSWORD?'[br]";

Instead of giving something to Orc:

say "[co]Bribery will not help you here. Orcs are, apparently, incorruptible.[/co]";

Instead of going south in Ket-orcroom when Orc is hostile:

say "The Orc says[br]'You may not pass.'"

Instead of talpsing in Ket-orcroom:

if talps-heard is true begin;

say "The ORC steps aside.";

now orc is amiable;

otherwise;

say "Are you talking to yourself[note 207]?";

end if;

Ket-deadend is a dark room in Ket-caves. "We are in a dead end. The east wall is in mint condition." Ket-deadend is east of Ket-archceiling. The helptext of Ket-deadend is "For a hole try a mixed up loop[note 175]!"

Every turn when the player is in Ket-deadend:

say "You hear voices coming from the other side of the wall."; [maybe more narrow conditions]

Instead of waving wand when the current game is mountains of ket and the player is in Ket-deadend: say "Magic glows at its tip!";

Ket-spiralstaircase is a dark room in Ket-caves. "A spiral staircase leads down from here into darkness. We are in a damp room and the sound of water comes from the south." Ket-spiralstaircase is south of Ket-orcroom.

Ket-lake is a watery dark room in Ket-caves. "We are standing on the north edge of an underground lake." Ket-lake is south of Ket-spiralstaircase.

Instead of going south in Ket-lake when the player carries five things:

say "GLUG! GLUG![p]You try to swim but the weight of your equipment pulls you under and you drown.";

deathify 9;

wait for any key;

carry out the escaping activity with Mountains of Ket;

Ket-midlake is a watery dark room in Ket-caves. Ket-midlake is south of Ket-lake. The description of Ket-midlake is "We are in the middle of the lake. A few yards away to our south is a beach."

Instead of going north in Ket-midlake:

say "GURGLE! UGH![p]You swim against the current and suddenly get pulled under by a very long tentacle and eaten alive.";

deathify 10;

wait for any key;

carry out the escaping activity with Mountains of Ket;

a crimson Fish is a masc thing in Ket-midlake.

The hisp of fish is "peces carmesí". Understand "herring" or "red" as crimson fish. Understand "peces" or "carmesi" or "herring" or "kipper" as crimson fish.

The description of crimson fish is "Oh, how amusing. You certainly never tire of this particular joke. Fresh every time."

Ket-littlebeach is a watery dark room in Ket-caves. Ket-littlebeach is south of Ket-midlake. Ket-lake is north of Ket-littlebeach.

a Ogre is a person in Ket-littlebeach.

Playing is an action applying to one thing. Understand "play [something]" or "roll [something]" as playing.

Instead of playing a game: try opening the noun.

Instead of playing:

if the player carries pair of dice begin;

say "[co]That's only going to work with the dice.[/co]";

otherwise;

say "[co]That's a verb of very specific usage, not applicable here.[/co]";

end if;

Instead of playing the dice:

say "With whom?";

Instead of playing pair of dice when the location of player is Ket-littlebeach:

if Magic sword is in Ket-littlebeach begin;

say "[co]Like the combat in Ket, there is no trick here other than save-scumming; it's better than fighting, at least, because it's over more quickly.[/co][p]He gives you his MAGIC SWORD.";

now the player carries magic sword;

otherwise;

say "The Ogre says[br]'I have nothing left to gamble.'";

end if;

a Magic sword is a sharp valuable thing in Ket-littlebeach.

The hisp of magic sword is "espada mágica". Understand "espada" or "magica" as magic sword.

The description of magic sword is "It's been a while since you've had your hands on one of these. They're intermittently helpful, true, but shopkeepers catering to the plundering-hero market will take them off your hands at a price too good to refuse. This one is a Viking or Saxon-looking thing, all burnt grey-black, with two or three horrible ragged notches torn into the blade."

The epilogue of magic sword is "worth an obscene number of denars to some half-drow with cleavage-window platemail who didn't put any points into Haggle".

the empty bottle is a thing in Ket-spiralstaircase.

The hisp of empty bottle is "botella vacía". Understand "botella" or "vacia" as empty bottle.

The description of empty bottle is "A tall, thin cylinder, the sort of size in which you might buy an exotic-looking and moderately expensive liqueur that you hadn't actually had a taste of yet."

the Bottle of water is a thing.

The hisp of bottle of water is "botella de agua". Understand "botella" or "agua" or "botella de agua" as bottle of water.

The description of bottle of water is "A tall, thin cylinder, the sort of size in which you might buy an exotic-looking and moderately expensive liqueur that you hadn't actually had a taste of yet. It's full of ordinary water."

the Bottle of oil is a burnable thing.

The hisp of bottle of oil is "botella de aceite". Understand "botella" or "aceite" or "botella de aceite" as bottle of oil.

The description of bottle of oil is "A tall, thin cylinder, the sort of size in which you might buy an exotic-looking and moderately expensive liqueur that you hadn't actually had a taste of yet. It's full of a brown-black oil."

Pouring is an action applying to one thing. Understand "pour [something]" or "empty [something]" as pouring.

Instead of pouring something: say "You can't do that.";

the Bottle of elixir is a thing.

The hisp of bottle of elixir is "botella de elixir". Understand "botella" or "botella de elixir" as bottle of elixir.

The description of bottle of elixir is "A tall, thin cylinder, the sort of size in which you might buy an exotic-looking and moderately expensive liqueur that you hadn't actually had a taste of yet. It contains... something shimmering that seems to squirm about of its own volition, like quicksilver on party drugs."

Instead of filling something (called foo):

if foo is a container begin;

say "You don't have anything to fill that with.";

otherwise;

say "You can't really fill that with anything.";

end if;

Instead of filling bottle of water: say "It's already full of water.";

Instead of filling bottle of oil: say "It's already full of oil.";

Instead of filling bottle of elixir: say "It's already full of elixir.";

Instead of filling empty bottle in a watery room:

say "[if the current game is Mountains of Ket]O.K. Its full[otherwise]You fill the bottle up with water.[end if].";

remove empty bottle from play;

now empty bottle is not safe;

now player carries bottle of water;

The elixir-count is a number that varies.

The elixir-count is 0.

Instead of filling empty bottle in Ket-shrine:

if elixir-count > 0 begin;

say "Seeing your greed, the GOD of the shrine hurls a lightning bolt at you.[br]O.K. Its full.";

deathify 14;

wait for any key;

now bottle of elixir is in Ket-shrine;

remove empty bottle from play;

now empty bottle is not safe;

carry out the escaping activity with Mountains of Ket;

otherwise;

say "O.K. Its full.";

remove empty bottle from play;

now the player carries bottle of elixir;

end if;

now elixir-count is elixir-count + 1;

Instead of drinking bottle of water:

say "[if the current game is Mountains of Ket]Glug! Glug! Aah[otherwise][We] chug[-s] down some refreshing water[end if].";

remove bottle of water from play;

now bottle of water is not safe;

now player carries empty bottle;

[jumpful is a truth-state that varies. jumpful is false.]

Instead of drinking bottle of elixir:

say "[if the current game is Mountains of Ket]Glug! Glug! Aah.[br]You feel a spring in your step[otherwise][We] drink[-s] the elixir in a couple of gulps. It has the distinctive burdock taste (and tweaky mental effects) of a jumping potion[end if].";

remove bottle of elixir from play;

now bottle of elixir is not safe;

now player carries empty bottle;

now player is springy;

unjumpification happens in three turns from now;

At the time when unjumpification happens:

say "The spring has gone from [our] step.";

now player is not springy;

Filling is an action applying to one thing. Understand "fill [something]" as filling.

Ket-oilroom is down from Ket-spiralstaircase. Ket-oilroom is dark. Ket-oilroom is in Ket-caves. "You must watch your step here as the floor has oil on it. From the south comes a musty smell[one of][or][or].[p]I told you it was slippery, you fall over[or][stopping]."

Instead of filling empty bottle in Ket-oilroom:

say "O.K. Its full.";

remove empty bottle from play;

now empty bottle is not safe;

now the player carries bottle of oil;

Ket-cellar is south of Ket-oilroom. Ket-cellar is dark. Ket-cellar is in Ket-caves. "The musty smell & many bottles indicate that this is a cellar[br]"

some Gold bars are a valuable thing in Ket-cellar.

The hisp of gold bars is "barras de oro". Understand "barras" or "oro" or "barras de oro" as gold bars.

The description of gold bars is "A dangerous colour, and heavy as sin. But quite emphatically plural."

The epilogue of gold bars is "which you trade with a homesteader for a lifetime's supply of Matanuska Thunderfuck, deal void in event of apocalypse"

Goblin2 is a person in Ket-cellar. The printed name of Goblin2 is "Goblin". Understand "goblin" as goblin2.

Instead of taking gold bars in the presence of Goblin2:

say "The Goblin says[br]'I'll give you the GOLD, i f you give me something to ease my boredom.'"

Instead of giving Gazette to Goblin2:

say "The Goblin says[br]'That'll do nicely, here's the GOLD'[br]";

now the player carries gold bars;

remove Gazette from play;

now Gazette is not safe;

Instead of giving vibrator to goblin2:

say "The Goblin says[br]'You are making some intrusive assumptions about my preferences'[br]";

Instead of giving five-foot chain to goblin2:

say "The Goblin says[br]'You are making some intrusive assumptions about my preferences'[br]";

Instead of giving five-foot chain to goblin2:

say "The Goblin says[br]'You are making some intrusive assumptions about my preferences'[br]";

Instead of giving gold bars to goblin2:

say "[co][if the player encloses gold bars]No returns.[otherwise]He's already got the gold bars[end if].[/co]";

Instead of giving a valuable thing to Goblin2:

say "The Goblin says[br]'That will never stand up to gold as a medium-term investment, do you have any BITCOINS'[br]";

Instead of giving coins to Goblin2:

say "The Goblin says[br]'Unbacked currencies are effectively worthless'[br]";

Instead of giving a book to Goblin2:

say "The Goblin says[br]'I demand entertainment not elitist intellectualism'[br]";

Instead of giving diary to Goblin2:

say "The Goblin says[br]'I may be a loathsome cellar-dwelling goldbug, but you've got problems, buddy'[br]";

Ket-skullroom is a room in Ket-caves. Ket-skullroom is south of Ket-crosspassage. The description of Ket-skullroom is "We are standing in front of a huge SKULL that blocks the passage, its eyes emit a dull red glow that lights the area[first time]. [p]You see a man wearing a long robe and tall hat pass through the skulls mouth. The mouth then closes[only]."

skullfuck is a truth-state that varies. skullfuck is false.

Every turn when the player is in Ket-skullroom:

if the player wears mages hat and the player wears mages cloak and the player wears false beard and skullfuck is false begin;

say "The SKULLS mouth opens revealing a room beyond.";

change the south exit of Ket-skullroom to Ket-redcurtain;

change the north exit of Ket-redcurtain to Ket-skullroom;

now skullfuck is true;

end if;

Ket-redcurtain is a room in Ket-caves. The description of Ket-redcurtain is "We are in a room with red curtains on all walls & a set of stairs going down."

A suit of magic Armour is an outfit in Ket-redcurtain. The description of Armour is "It looks very strong!"

a Giant Zombie is a monster in Ket-redcurtain.

Instead of going down in Ket-redcurtain:

say "The Giant Zombie blocks you.";

Instead of going down in Ket-redcurtain when the player wears magic luck ring and the player wears magic armour:

say "TAPE 2[p]You have found the way through the mountains and can now begin the journey to the Temple where you will find Vran & Delphia.[p]Do you have TAPE 2 ?[p][co]...Nooooooooope. And you certainly wouldn't be able to find it anywhere, either. No indeed.[/co]";

wait for any key;

carry out the concluding activity with Mountains of Ket;