IFDB Spelunking 2 — 18 of 18

Part 7 - Down and Out

Big Creepy House is a game in startroom. The precis of Big Creepy House is "[set link 506][bold type]Down and Out at the Big Creepy House on the Poison Lake[roman type][end link]

by Shii (2009)[line break]

1.5/5 stars".

The printed name of Big Creepy House is "Down and Out at the Big Creepy House on the Poison Lake".

The description of Big Creepy House is "[b]Down and Out at the Big Creepy House on the Poison Lake[/b][line break]by Shii[note 24][br]Magical realism[line break]2009[p][b]About the Story[/b][br]Yeah, so it looks like I'm a dope and wrecked my boat at this nasty old house.[p]Development System: Inform 7[br]Forgiveness Rating: Nasty[p][b]1st Annual MetaFilter Interactive Fiction Contest[note 25][/b][p][b]Tags:[/b] 1st Annual MetaFilter Interactive Fiction Contest (8) cover art (513) profanity (44) strong profanity (78[note 109])[p][co]There's a substantial review by C.E.J. Pacian, which you skim: 'promising', 'woefully untested', 'a catalogue of rookie errors', 'a fair few imaginative flourishes', 'I have to admit that I'm stumped.' Oh dear. This may call for a quick smash-and-grab, lest you be sucked down into a quagmire. On the other hand, it's a .z5 written in Inform 7, so how big could it really be?[/co][p][set link 526][b]Open it up.[/b][end link]".

To reset Big Creepy House:

if slave driver is in Poison Lake, now slave driver is in bsh-boathouse;

if slave driver is in bsh-boathouse, now driver-intro is true;

Understand "poison" or "lake" or "down and out" as Big Creepy House.

Carry out opening Big Creepy House:

clear the screen;

reset Big Creepy House;

if Big Creepy House is unplayed begin;

say "Uh. It looks like I'm in a strange bedroom. That's pretty cool. So... yeah. What was I doing? I can't believe this... I've forgotten again[note 147]. I gotta retrace my steps. Um... I was rowing across the lake... in a boat, right. Then I saw this really weird shaped house, on a rocky island. Damn, and my boat got swept up against the rock, too! Yeah, that's what happened--my head slammed into a cleat! That really hurt! That must be why I passed out... what was I doing on the lake in the first place, though? I was looking for something. It was pretty important, I remember that. Oh, this isn't good. No, I can't seem to remember much at all. Who am I, anyway? I don't even know my name! Christ, this is embarrassing. I feel like I'm playing out the most basic trope in the book. The first thing they teach you is never to stay out too long in the mist...[br]It would be nice to know who 'they' were, though[note 107]...[p]";

wait for any key;

end if;

say "[b]Down and Out at the Big Creepy House on the Poison Lake[/b][br]A story from the Mist universe[note 106] by Shii[br]Release 5 / Serial number 090402 / Inform 7 build 5U92 (I6/v6.31 lib 6/12N)[br]";

now the player is in bch-bedroom;

now the story viewpoint is first person;

accomplish accomp7;

wardrobe-change pajamas;

my pajamas are an outfit. The description of pajamas is "A plaid slip-on shirt and pants. I can't seem to recall bringing these with me. Come to think of it, it would be rather weird if I had been rowing across a lake in my PJs." Understand "pyjamas" and "PJs" and "pijama" as pajamas. The hisp of pajamas is "pijama". The printed name of my pajamas is "[our] pajamas".

Does the player mean doing something to the pajamas: it is very likely.

Instead of taking off pajamas when the current game is Big Creepy House: say "While I'm not a huge fan of these pajamas, the alternative is not exactly appealing."

pajama pockets are an unimplement. pajama pockets are part of pajamas. Understand "pocket" as pajama pockets.

Instead of examining the player when the current game is Big Creepy House:

say "Yup, I'm me! I lost my name but I can still recognize myself. I'm in pretty good shape considering what I've been through[if the player wears pajamas]. I am wearing horrid pajamas though[end if]."

Instead of eating something when the current game is Big Creepy House:

say "I'm starting to doubt my own sanity. For a moment there I had an intense desire to eat [the noun].";

bch-bedroom is a room. "Judging by the dust on the vanity and the melted lamp, I don't think this bedroom has been used in a long time, except by yours truly. It's rather stately, though. I've never slept in a canopy bed before. Everything looks antique and hand-carved. There's Victorian wallpaper on the walls, and the floor is polished wood.[p]A bay window illuminates a whole shelf full of books. Through a door to the south is the hallway." The printed name of bch-bedroom is "Bedroom".

The saferoom of Big Creepy House is bch-bedroom.

the vanity is scenery in bch-bedroom. "A dusty white vanity with a mirror and so forth."

the mirror-v is part of vanity. The printed name of mirror-v is "vanity mirror". Understand "vanity" or "mirror" or "oval" as mirror-v. The description of mirror-v is "A cloudy oval mirror sits on the vanity, covered in dust."

Instead of taking mirror-v: say "I think about taking the vanity mirror with me, but it's probably better off where it is."

a melted lamp is scenery in bch-bedroom. "An old metal lamp hanging from the wall, containing a melted candle. Good thing it's light out."

the canopy bed is a supporter in bch-bedroom. The description of canopy bed is "This is a canopy bed with white drapes. It's in rather good shape. All the sheets are white and the pillow is stuffed with feathers. The posts are elegantly lacquered.". canopy bed is enterable. canopy bed is scenery.

the posts are part of the canopy bed.

the candle is scenery in bch-bedroom. Instead of taking the candle: say "I'm afraid the candle is not salvageable. It's just a little ring of wax."

candle is burnable.

the pillow is scenery in bch-bedroom. The description of pillow is "A white feather pillow that was supporting my head just a short while ago." Instead of taking pillow: say "I've no need for a pillow, and I've only got two hands and pockets anyway."

the bch floor is scenery in bch-bedroom. The description of bch floor is "Long wooden boards. Looks, like, glazed." The printed name of bch floor is "floor".

the bay window is scenery in bch-bedroom. "So, there's this nice plush seat jutting out of the wall, and around it are three window panes at acute[note 108] angles to each other. That's what a bay window looks like."

the seat is part of bay window. seat is an enterable supporter. The description of seat is "A plush red window seat covered in dust." [Instead of sitting on bay window: try sitting on seat.]

Instead of searching bay window: say "Mist."

wallpaper is scenery in bch-bedroom. "Old, yellowed wallpaper with blue fleurs-de-lis."

bookshelf is scenery in bch-bedroom. bookshelf is a container. "This is the queerest bookshelf I've ever seen[note 135]. All of the books are definitely waterlogged, but we're on the second floor! Maybe there was a flood in their previous location." Understand "books" or "shelf" as bookshelf.

a book is a kind of thing. a book is usually burnable. Understand "book" or "libro" as a book.

A thing can be hisp-proper. A thing is usually not hisp-proper.

the Almagest is a book in bookshelf. The description of Almagest is "A book about astronomy called the Almagest. Doesn't look too useful to [us]."

The hisp of Almagest is "Almagesto". Understand "almagesto" as Almagest.

the Didache is a book in bookshelf. The description of Didache is "A book about religion called the Didache. Doesn't look too useful to [us]."

The hisp of Didache is "Didaché".

the Talmud is a book in bookshelf. The description of Talmud is "A book about religion called the Talmud. Doesn't look too useful to [us]."

Leviathian is a book in bookshelf. The description of Leviathian is "A book about philosophy called Leviathian[note 181]. Doesn't look too useful to [us]."

The hisp of Leviathian is "Leviatán". Understand "Leviathan" or "Leviatan" as Leviathian.

Metamorphoses is a book in bookshelf. The description of Metamorphoses is "A story called Metamorphoses. Doesn't look too useful to [us]."

The hisp of Metamorphoses is "Las metamorfosis". Understand "metamorphosis" or "metamorfosis" or "las metamorfosis" as Metamorphoses.

The City of God is a book in bookshelf. The description of The City of God is "Never heard of this book before. Someone called Augustine wrote this. What a weird name."

The hisp of City of God is "La ciudad de Dios". Understand "ciudad de dios" or "ciudad" or "dios" or "la ciudad de dios" as City of God. City of God is hisp-proper.

the Colliget is a book in bookshelf. The description of Colliget is "'The Colliget of Averroes' is printed on the cover. It looks like philosophy."

the Bottle Manuscript is a book in bookshelf. The description of Bottle Manuscript is "The words 'Bottle Manuscript' are written on the cover of this book in spider-like ink. The book appears to be bound in leather, using string instead of glue for the spine."

The hisp of Bottle Manuscript is "el Manuscrito Botella". Understand "manuscrito" or "botella" as Bottle Manuscript. Bottle Manuscript is hisp-proper.

the Symposium is a book in bookshelf. The description of Symposium is "A book about philosophy called the Symposium. Doesn't look too useful to [us]."

The hisp of Symposium is "Simposio". Understand "simposio" as Symposium.

the Iliad is a book in bookshelf. The description of Iliad is "A story called the Iliad. Doesn't look too useful to [us]."

The hisp of Iliad is "La Ilíada". Understand "iliada" as Iliad. Iliad is hisp-proper.

the Life of Cuthbert is a book in bookshelf. The description of Cuthbert is "It looks like an ancient hagiography. How absolutely scintillating."

The hisp of Cuthbert is "La vida de San Cuthbert". Understand "vida" or "san" as Cuthbert. Cuthbert is hisp-proper.

the Aeneid is a book in bookshelf. The description of Aeneid is "A story called the Aeneid. Doesn't look too useful to [us]."

The hisp of Aeneid is "La Eneida". Understand "eneida" as Aeneid. Aeneid is hisp-proper.

Understand the command "read" as something new.

reading is an action applying to one thing. Understand "read [something]" as reading.

Instead of reading something (called foo): try examining foo.

Instead of opening a book: say "Yup, there are pages in the book."

Instead of reading a book (called foo) when the current game is Big Creepy House:

if foo is Bottle Manuscript begin;

say "I open the manuscript to page 1.[p]I see on page 1: 'Bottle ms., found year 27, retranscribed year 50[p]If anyone reads this please let me know. I put this message in a bottle and dropped it in the river just outside my city's walls-- I assume the river goes somewhere. I don't know the real name of the river, or the city. Sorry.'[p]A twelve-page[note 182] message in a bottle?";

otherwise;

say "While I do love to read in my free time, I feel there are more important things I need to do in this weird old house than read [the foo].";

end if;

After consulting Bottle Manuscript about a topic listed in the Table of Bottledom:

say the desc entry;

say "[br]";

Table of Bottledom

bsh-hallway is south of bch-bedroom. "The hallway is dark and quite narrow--there's barely enough room for me to stretch out my arms. There's this weird painting on the wall, too.[p]There's a metal spiral staircase leading up and down. It's dark up there, though! If I go north, I'll be back in the bedroom where I started. There's another door to the south... I wonder where it goes?" The printed name of bsh-hallway is "Hallway".

the portrait is scenery in bsh-hallway. "It's a portrait of this really old guy. His fingers are all shriveled up and his skin is gray. His face looks like a skull. It's making me shiver![p]The frame says 'Charles Young II'. No date." Understand "painting" as portrait.

up staircase is an open scenery door. up staircase is above bsh-hallway and below bsh-topstairs.

bsh-topstairs is a dark room. The description of bsh-topstairs is "There's not much here but a metal door opening out to the roof. I can see the stairs spiraling all the way down into the kitchen. Good thing there's a railing!" The printed name of bsh-topstairs is "Top of the Stairs".

Rule for printing the description of a dark room when the location is bsh-topstairs: say "Darkness, shmarkness, go to Barkness[note 208]!"

Before going up from bsh-topstairs:

say "[first time]I involuntarily cover my mouth as I step outside... my reflexes must have expected mist. But there's nothing but clear air before me, and a nice big view.[br][only]";

the metal door is a closed locked scenery door. metal door is outside from bsh-topstairs and inside from Widow's Walk. The description of metal door is "Metal, covered in illustrations of twisting vines. The sort of door that opens into a secret garden."

brass key unlocks metal door.

Widow's Walk is a room. "Woah-- I'm on top of the world! This must be a widow's walk, because it's on top of the roof and surrounded by railing. This is amazing, I can actually see almost all the way out to the horizon to the south. Clouds cover the sky; the island is surrounded by a wall and a beach. On my east and west are rolling hills, and in the north a polluted river is dumping all kinds of trash into the lake around the house. I think this deserves a look around."

the hills are scenery in Widow's Walk. Understand "east" as hills. The description of hills is "There are hills on either side of this lake. They're covered in uninhabited forest. If I came to this island from some sort of port town, I can't see it through the mist."

the river is scenery in Widow's Walk. Understand "north" as the river. The description of river is "The stream rolls downhill from somewhere obscured by mist into the lake. It can't be very deep, because parts of it are clogged up with junk."

the roof is scenery in Widow's Walk. Understand "house" as roof. The description of roof is "The roof is covered in dark blue shingles and is almost circular. There's a cranny on the north face of the house, where the bay window is. I can make out a garden on the ground."

the railing is scenery in Widow's Walk. The description of railing is "A wooden railing, covered in peeling white paint, surrounds me entirely, except where it meets the door inside. That's where the roof rises up."

the garden is scenery in Widow's Walk. The description of garden is "On the ground of this island is a garden surrounded by a high wall. It looks kind of dead down there! I see some movement, though. It's coming from inside a house built in to one of the walls. There are shadows flickering around. Is the person who rescued me down there? There's a sundial and stuff like that, too."

the bsh-walls is scenery in Widow's Walk. The description of bsh-walls is "There's a quite high wall made apparently of stone that goes all the way around this little island. It actually is made up of three parts: a white inner wall, a black outer wall, and a thick layer of bird skeletons in between the two. It creeps me out a little." The printed name of bsh walls is "walls". Understand "skeletons" or "wall" as bsh-walls.

the horizon is scenery in Widow's Walk. The description of horizon is "The mist-covered lake extends all the way out to the horizon, covered completely in trash." Understand "south" as horizon.

the distant lake is scenery in Widow's Walk. The description of lake is "This lake is mostly obscured by mist, but I can see garbage everywhere."

the mist is scenery in Widow's Walk. The description of mist is "Mist permeates everything from the ground level up to the tops of the hills. In fact, it rises up to the island itself, but something weird is going on. It looks like the mist stops at this thick wall around the island that's covered in little skeletons."

the garbage is scenery in Widow's Walk. "It's impossible to describe how much junk there is in the water. I spot some umbrellas, clothing, furniture, books, lots of paper, discarded food containers, and televisions. Near the mouth of the lake I see an entire car blocking the river. No sign of my rowboat, though." Understand "junk" as garbage.

the beach is scenery in Widow's Walk. "There's a thin beach on the northern end of the island. The beach stands about fifty feet below the walls, and it's covered in trash from the lake. I can't quite make it out, but it looks like there's a human body there...?!"

the human body is an unimplement in Widow's Walk. the car is an unimplement in Widow's Walk.

the clouds are a backdrop. clouds are in Widow's Walk and bsh-garden. The description of clouds is "The sky is gray and full of clouds. I can't make out the sun in this weather." Understand "sky" or "sun" or "cloud" as clouds.

the down staircase is an open scenery door. down staircase is below bsh-hallway and above bsh-kitchen.

Before going south in bsh-hallway for the first time:

say "As I carelessly open the door, a putrid stench floods my nostrils, causing my eyes to involuntarily tear up.[bathe 4]";

bsh-bathroom is south of bsh-hallway. "Here's hoping I don't have to use this bathroom anytime soon. I think someone ran out of Scrubbing Bubbles a long time ago. Streaks and lines on the ceramic tiled walls are good evidence of futile efforts to clean the grime and mold off with a washcloth... many years ago. The floor is probably linoleum, but let's not think about the floor too much. There's also normal bathroom stuff in here like a sink, a shower, a mirror, etc." The printed name of bsh-bathroom is "Bathroom". bsh-bathroom is watery.

Instead of smelling in bsh-bathroom: say "I smell nothing unexpected[note 201]."

the ceramic tiles are scenery in bsh-bathroom. "What can I say about bathroom tiles? White, ceramic squares. Moldy, of course. There's a towel rack attached to one of the walls."

the bsh-towel rack is a scenery supporter in bsh-bathroom. "A perfectly ordinary towel rack[if towel is on bsh-towel]. There's even a towel on it[end if]." Understand "towel rack" or "towel" as bsh-towel rack. The printed name of bsh-towel is "towel rack".

a towel is on bsh-towel rack. The description of towel is "I should always remember where my towel is."

The hisp of towel is "toalla". Understand "toalla" as towel.

towel is wearable.

Rule for writing a paragraph about towel when towel is on bsh-towel: do nothing.

Before printing a locale paragraph about bsh-towel rack:

if towel is on bsh-towel rack, now towel is mentioned;

Before examining bsh-towel rack: now towel is scenery.

After examining bsh-towel rack: now towel is not scenery.

After taking towel for the first time: say "Taken.[br][bracket]Your score has just gone up by one point.[close bracket][note 132][br]".

Before going down in bsh-hallway: say "[first time]I stomp down the spiral staircase, and a marvelous old room appears before my eyes.[only]";

the bsh-sink is scenery in bsh-bathroom. The printed name of bsh-sink is "sink". The description of bsh-sink is "This sink is gross. There's some sort of brown growth lining the basin. The faucet has its cap missing -- looks broken to me." Understand "sink" as bsh-sink.

a faucet is part of bsh-sink. The description of faucet is "A most definitely broken tap."

the bsh-floor is scenery in bsh-bathroom. "I'm guessing linoleum. I'm perceiving mostly brownness." The printed name of bsh-floor is "floor". Understand "floor" as bsh-floor.

the bsh-toilet is scenery in bsh-bathroom. The description of bsh-toilet is "No, let’s not examine that toilet too closely, okay?" Understand "toilet" as bsh-toilet. The printed name of bsh-toilet is "toilet".

the bsh-shower is scenery in bsh-bathroom. "Yup, it's a gross old shower. No surprises here." The printed name of bsh-shower is "shower". Understand "shower" as bsh-shower.

Instead of entering bsh-shower: say "That's not something I can enter[note 157].";

the bsh-mirror is scenery in bsh-bathroom. "No medicine cabinet behind this mirror -- just good old foggy glass." The printed name of bsh-mirror is "mirror". Understand "mirror" as bsh-mirror.

Instead of searching bsh-mirror: say "I spy in the mirror a classy-looking person wearing [random outfit worn by the player]. Hey, that's me! Too bad I don't know my name, or I'd ask me out.[p]My hair looks a little messy. Too bad there's no comb around here."

bsh-kitchen is a watery room. "Here's fun! This room with the high ceiling is clearly an abandoned kitchen. I don't see any food anywhere, but with a wooden table, a brick oven built into one of the walls, and a cabinet on the opposite wall with a counter on top, it's difficult to conclude anything other than 'kitchen'. What's especially great about this kitchen, in my opinion, is that an iron staircase is spiraling right out of the floor and up to the second story. There's also a window with a diamond-shaped panel in the middle, illuminating the table and chairs. To the west there's a door leading outside." The printed name of bsh-kitchen is "Kitchen".

the kitchen table is a supporter in bsh-kitchen. The description of kitchen table is "A table good enough to eat off of[note 119]."

a brass key is a masc tiny thing on the kitchen table. "A heavy-looking brass key is sitting on the table, waiting eagerly to be dropped into my pajama pocket." The description of brass key is "With an ovaloid bow, and a single rounded notch for a bit, this key is decidedly old-school."

Rule for writing a paragraph about kitchen table:

if kitchen table supports brass key begin;

now brass key is mentioned;

say "A heavy-looking brass key is sitting on the table, waiting eagerly to be dropped into my pajama pocket.";

otherwise;

do nothing;

end if;

The hisp of brass key is "llave de latón". Understand "llave" or "laton" or "llave de laton" as brass key.

the counter is a scenery supporter in bsh-kitchen. The description of counter is "A counter pocked with the scratches and dents of many years of veggie chopping. There's a wooden chopping board glued to it."

a chopping board is on the counter. The description of chopping board is "Someone apparently didn't like their chopping board moving around. It's glued tight."

Instead of taking chopping board when chopping board is on counter: say "I can't seem to separate it from the counter."

a matchbox is on the counter. The description of matchbox is "A box of matches from the Downtown Cafe and Eatery. It has a little strip of that gray stuff you strike matches on." Understand "box" or "matches" or "box of matches" or "caja" or "cerillas" or "caja de cerillas" or "matchbook" or "matches" as matchbox.

The hisp of matchbox is "caja de cerillas". Understand "caja" or "cerillas" or "caja de cerillas" as matchbox.

matchbox is an openable container. matchbox is closed.

A match is a kind of thing. four matches are in matchbox. The description of a match is usually "This is a match. [We] can strike it on something." The hisp of a match is usually "cerilla". Understand "cerilla" as a match. A match is tiny.

Striking it against is an action applying to two things. Understand "strike [something] against [something]" or "strike [something] on [something]" as striking it against.

Does the player mean striking a match against the matchbox: it is very likely.

Carry out inserting something into matchbox:

if the noun is an animal begin;

say "Disturbingly, [the noun] fits inside the matchbox, but it clearly has no intention of remaining there. After a few failed efforts, involving some gut-churning distortions of space-time, [we] give[s] up.";

stop the action;

end if;

Report inserting something into matchbox:

if the noun is not tiny begin;

say "[one of]Oh ho ho ho. This is one of those unfortunate objects that has no rationality limits on containment. In the outside world, they're unstable - only lasting a few precious weeks - but in the deep tunnels they can be invaluable workarounds for certain onerous rules. (Which is to say, employ with caution, because it will sure as hell break things.) And once you get out, it has a number of quite profitable applications, though few of them are exactly what you'd call legal[or]Hee hee. That never gets old[stopping].";

now matchbox is valuable;

end if;

Instead of striking something against something: try attacking the second noun.

Instead of burning a match (called foo):

if the player carries matchbox begin;

try striking foo against matchbox;

otherwise;

say "This is a safety match; you'll need to strike it against the box.";

end if;

Instead of striking a match against something (called foo):

say "[if the current game is Big Creepy House]I feel kind of silly rubbing the match against [the second noun][otherwise]Apparently it's a safety match. You'll need to use the box[end if].";

Instead of striking a match against matchbox:

if the player does not carry the noun begin;

say "(first taking a match)";

try silently taking the noun;

end if;

say "The match catches fire! This match is kind of stubby, so I should figure out what I want to do with it, like, right now.";

now the printed name of the noun is "burning match";

now the noun is lit;

matchdrop happens in two turns from now;

matchsputter happens in three turns from now;

At the time when matchdrop happens:

if the player carries a lit match begin;

say "The match is almost totally aflame!";

let N be a random lit match carried by the player;

try dropping N;

end if;

At the time when matchsputter happens:

let N be a random lit match;

if N is visible, say "The burning match turns to ash.";

remove N from play;

Instead of doing something other than dropping with a lit match:

say "The burning match is kind of on fire right now. I'd prefer to let the fire do its own thing.";

Instead of doing something when the second noun is a lit match:

say "The burning match is kind of on fire right now. I'd prefer to let the fire do its own thing.";

the brick oven is a container in bsh-kitchen. brick oven is scenery. The description of brick oven is "A brick oven with a small, hemispherical opening giving way to a big space behind it in the wall. It looks like there's enough stray bits of charcoal back there for it to work properly. If I fed this thing enough wood, it could probably bake me a whole batch of cookies. Yum!"

the brick oven can be fiery or chilled. the brick oven is chilled.

Check removing something from fiery oven:

say "It looks like we've got a nice fire going in the burning brick oven. I don't want to reach inside right now.";

stop the action.

Rule for printing the name of a fiery brick oven: say "burning brick oven".

some stray bits of charcoal are an unimplement in bsh-kitchen.

the bsh cabinet is a closed scenery container in bsh-kitchen. The description of bsh cabinet is "I lean down to inspect the cabinet. There's no lock on it-- just It is made of stained and finished wood. All around, a nice cabinet. There's a counter on top.[if closed] It's closed at the moment[end if]." The printed name of cabinet is "cabinet". bsh cabinet is openable and closed.

the stone idol is a thing in bsh cabinet. The description of stone idol is "A tiny, hand-carved stone statue. It looks like a little gargoyle."

The hisp of idol is "ídolo de piedra". Understand "idolo" or "piedra" or "idolo de piedra" as idol.

the wooden box is a closed locked container in bsh cabinet. The description of wooden box is "A varnished wooden box. It has a weird-shaped lock and it's covered in mysterious curly engravings. I bet there's something really cool inside!"

The hisp of wooden box is "caja de madera". Understand "caja" or "madera" or "caja de madera" as wooden box.

the diamond window is scenery in bsh-kitchen. "This window has five panels. Four are arranged in a square, and the fifth diamond-shaped one is wedged into the middle."

the kitchen door is a scenery door. kitchen door is west of bsh-kitchen and east of bsh-garden. kitchen door is closed.

bsh-garden is a room. "An overgrown garden surrounded by a high, whitewashed wall. Looking up to the gray sky, I see that the wall seems to block the mist somehow. The sky is clear, albeit gray, directly above me. There's a sundial that casts no shadow, and the hedges need to be clipped badly. To the east is the house. To the north there's an interesting sort of shack. It's built into the wall and seems to slope underneath it. I think it's a boathouse!" The printed name of bsh-garden is "Garden".

the sundial is scenery in bsh-garden. "A stone sundial with a curved gnomon stands in the middle of the garden on a pedestal. Since it's such a cloudy day, you can't see any shadow at all. The wabe is overgrown with tall grass."

the hedges are scenery in bsh-garden. "Originally snipped to right angles--now a mess of outgrowths and stray branches."

whitewashed wall is scenery in bsh-garden. The description of whitewashed wall is "A stone wall that's been smoothed over and whitewashed. It meets the walls of the house to the southeast and northeast."

house exterior is scenery in bsh-garden. The description of house exterior is "Here's the house I woke up in-- apparently the main attraction on this island. It's painted a dull gray with dark blue shingles. The bedroom window forms a lovely cranny. There's a widow's walk on the roof."

the wabe is part of the sundial. the description of wabe is "I see nothing special about wabe[note 143]."

gnomon is part of the sundial.

After examining house exterior for the first time:

bandname 4;

pedestal is an unimplement in bsh-garden.

grass is an unimplement in bsh-garden.

the boathouse door is a scenery door. boathouse door is north of bsh-garden.

driver-intro is a truth-state that varies. driver-intro is true.

bsh-boathouse is north of the boathouse door. The printed name of bsh-boathouse is "Boathouse".

The description of bsh-boathouse is "[if slave driver is in bsh-boathouse and driver-intro is true]I make out a boat inside the boathouse--could it be mine?! As I step inside eagerly, I hear a voice. 'So, you're awake,' says the voice, and I see an enormous bulk of a man wearing little but camouflage pants, a gas mask around his nose and mouth, and a scimitar. Hmm. This isn't exactly the best situation I could be in.[p]'What do you remember?' he asks, breathing through the mask.[p]'Nothing,' I reply honestly.[p]'Thought so,' the dude says brusquely. 'You were out long enough you probably forgot where you came from. You're an escaped slave.'[p]'What's my name?'[p]'You're the property of the Emperor. You don't get a name.'[p]'Who's the emperor?'[p]'Oh, shut up. Get in the boat and I'll give you your mask so we can get out of here.'[p]Welp. Here we are in the boathouse. [end if]I see a slave driver and a boat here. I ain't got much choice left."

After looking in bsh-boathouse:

now driver-intro is false;

continue the action;

After going north from bsh-garden for the first time:

say the description of bsh-boathouse;

bandname 5;

Instead of examining something in bsh-boathouse in the presence of slave driver:

if the noun is the slave driver begin;

say "The slave driver spots me looking around. 'None of that,' he says.";

otherwise;

continue the action;

end if;

Instead of going south in bsh-boathouse in the presence of slave driver:

say "Gee, I'd love to leave, but there happens to be this BIG DUDE WITH A KNIFE TELLING ME TO GET ON THE BOAT.";

gas mask is a wearable thing. The description of gas mask is "[if worn][We] [are+] looking through the two tinted eyeholes of a gas mask on loan to [us] from [our] friendly slave driver. It looks like there's some sort of canister attached to it below [our] left cheek[otherwise]A somewhat old-fashioned gas-mask with a sort of canister attachment instead of a filter.[end if]." Understand "canister" or "gasmask" as gas mask.

The hisp of gas mask is "careta antigás". Understand "careta" or "antigas" as gas mask.

Instead of taking off the gas mask when the player is in Poison Lake:

say "As I take off the gas mask, I feel a dizziness come over me almost immediately. It must be a combination of the mist and the stench from the lake.[p]'Put that back on!' yells the slave dude. I laugh for some reason and lunge at him, intending to throw him off the boat.[p]Oh wait, he has a knife-- I forgot about the knife--";

wait for any key;

deathify 22;

carry out the escaping activity with Big Creepy House;

slavestuck is a number that varies. slavestuck is 0.

Every turn when the player is in bsh-boathouse and slave driver is in bsh-boathouse:

now slavestuck is slavestuck + 1;

if slavestuck is 12 begin;

if the player carries revolver begin;

say "[co]The consciousness dawns on me that the slave driver has brought a knife - well, a scimitar - to a gun fight.[/co]";

otherwise;

if the player carries wooden box begin;

say "[co]You don't think you'll be able to get past this point until you've found a way into the wooden box.[/co]";

otherwise;

say "[co]You're missing the crucial item that lets you get past this stage. Maybe backtrack and search around some more.[/co]";

end if;

end if;

end if;

the rowboat is enterable scenery vehicle in bsh-boathouse. Understand "boat" as rowboat. gas mask is in rowboat.

The description of rowboat is "A sturdy little rowboat, suitable for going out to sea. The name 'H.H. MARKOS III' is written on the side[if there is a thing in the rowboat]. There is [a list of things in the rowboat] lying on its floor[end if]."

Instead of entering rowboat in the presence of slave driver:

say "I get into the rowboat.[p]Gripping my flailing arms under his armpit, the slave driver strips me of my clothing and throws it in the water with all my stuff.[p]'Hey!' I yell. 'What the hell are you doing?'[p]'Not your clothes,' he explains helpfully. 'You own nothing. Put this on.' He straps a gas mask over my head and ties my arms to the back of the boat.[p]As I attempt to protest through the mask, he chops the rope from its cleat, and the boat drifts into the lake.";

now everything safe carried by the player is in startroom;

now everything safe worn by the player is in startroom;

now horse is not ridden;

now everything carried by the player is in bch-bedroom;

now player carries safety line;

now everything worn by the player is in bch-bedroom;

now the player wears gas mask;

move slave driver to Poison Lake;

move the player to Poison Lake;

shitstorm happens in four turns from now;

Instead of pulling safety line when the location is Poison Lake:

say "[co]Uh-oh. Your hands are bound, and you can't reach the line.[/co]";

Instead of going north in bsh-boathouse when the slave driver's body is in bsh-boathouse:

if the player does not wear gas mask begin;

say "I can’t go out into the mist without a gas mask. I’d lose my head.";

otherwise;

if the player is in rowboat begin;

continue the action;

otherwise;

say "I don't think it's a good idea to swim outside. The lake is full of toxic trash that's probably leaked into the water.";

end if;

end if;

Lakeside Beach is north of bsh-boathouse. "Mist covers the water and trash lines the beach. A recent shipwreck is sprawled out on a rock. I can see a rocky cliff towering upwards and turning into one of the black walls before the mist obscures it completely. A girl lies on the beach."

Open Lake is north of Lakeside Beach. "Mist obscures everything but trash. Without a good idea of where I’m going I should probably turn back." Open Lake is east of Open Lake. Open Lake is north of Open Lake. Open Lake is west of Open Lake.

the shipwreck is scenery in Lakeside Beach. The description of shipwreck is "Another rowboat wrecked against the rocks. Hey, wait a minute... this is my boat! It doesn’t have any markings, but I remember the blue paint as if it were yesterday."

the cliff is scenery in Lakeside Beach. the description of cliff is "A quite unclimbable cliff. Rocks jut out from it at weird angles. Towards its top it merges with the smooth black stone of the outer walls."

the black stone walls are scenery in Lakeside Beach. the description of black stone walls is "Black stone as far up as I can see." Understand "outer" as black stone walls.

the girl is a woman in Lakeside Beach. girl is scenery. The description of girl is "She looks hurt. She’s wearing a black button-down shirt and a long black skirt. I think she was left here to die–without any kind of mask. I don’t know if she’s K.O.ed or what, but even as I walk up to her she’s not responding to any sort of noise. Her eyes are closed."

the black button-down shirt is an unimplement in Lakeside Beach. the long black skirt is an unimplement in Lakeside Beach.

Instead of doing something to girl when the player is in rowboat: say "I believe I will have to disembark from my rowboat in order to take a close look at this girl."

Instead of touching girl, say "I should keep my hands to myself."

Check taking off the gas mask:

if the player is in Lakeside Beach or the player is in Open Lake begin;

say "I’d have to be insane to take off my mask outside, after I remembered all of this!";

stop the action;

end if;

Does the player mean wearing the gas mask: it is very likely.

Does the player mean giving the slave driver's mask to girl: it is very likely.

Instead of giving the slave driver's mask to girl:

say "I strap the mask around the girl’s head. It covers just her nose and mouth. Her eyes open momentarily, then close again against the mist, and her head shakes a little. Well, she’s awake. Now I just need to wait.";

wait for any key;

say "A couple of minutes pass. She seems to be breathing normally. Eventually she opens her eyes again. '...get out,' she says.[p]'Huh?'[p]'The slaver is... we need to get out.'[p]'I killed him.'[p]'...good.' She falls asleep again.[p]She was following behind me on another boat–I remember now. We had snuck out of a town somewhere far upstream. She must have found me, carried me inside, and given me a change of clothes. She’s stronger than she looks! But her boat is nowhere to be seen. The slave driver must have cast it out on the lake.[p]The mist sweeps over me and clings to my pajamas.[br]I shiver a little.";

wait for any key;

say "About an hour later, she comes to again. This time, she sits up and looks at me. 'You escaped,' she says. She looks tired. 'Thank God.'[lady 5][p]'Well. The gun helped.'[p]'There was a gun in there?'[p]'Yeah...'[p]'...' She looks away, ashamed with herself.[p]'What’s my name?' I ask. 'And what’s yours?'[p]There’s a brief pause. Then she turns back to me, eyes wide. 'I... I don’t know!'[p]'Hey. That makes two of us.'[p]”;

wait for any key;

say "Hints of memories flit through my head. Our valley is too far from here to even think of going back to. The two of us have been away for a long time. She’s taken me across mountains, hiding in Mist-free caves with strange people. For years, even. But why?[p]'Were we on the run from that slave driver?'[p]She shakes her head.[p]'I didn’t think so either. But we’ve been on the run.'[p]'Yeah.'[p]'Why?'[p]She looks at me sternly. 'You... you always ask such stupid questions!'[p]'So you know?'[p]'There’s no way I could know! I’ve forgotten everything!' She tries to stand up, staggers a little, and falls on her butt.[p]'You remember me.'[p]She looks at me. The silence seems full of blessings.";

wait for any key;

say “'We were searching for something, weren’t we?'[p]'Yeah. It wasn’t here, though.'[p]'It wasn’t?'[p]'No... it was far away... over those hills.' She gestures west.[p]'It was really important,' I say to myself. 'I wonder what it was.'[p]'I’m sure we’ll find out soon enough.'";

wait for any key;

say “'We should get going,' she says, standing up in earnest.[p]'You’ll be leading again?'[p]She glares down at me. 'Look what happened when I let you lead!' she sighs petulantly. 'Never again!'[p]I smile. I know this fake anger, this dramatic insistence on going first. I remember all too well.[p]'Well,' I say, 'if you insist.'[p][b]*** You have won ***[/b]";

now the player carries true love;

carry out the concluding activity with Creepy House;

Before giving gas mask to girl:

say "This would involve taking the gas mask off my own head, which would be unwise.";

stop the action.

True Love is a valuable masc thing. The description of true love is "Ach, [we] hate[-s] it when the real treasure is true love. Most treasures don't make [us] uneasy when [we] sell[-s] them to pay for health insurance."

The epilogue of true love is "which slips through your clumsy fingers, leaving your life immeasurably richer and brutally poorer".

The hisp of true love is "verdadero amor". Understand "verdadero" or "amor" as true love.

Poison Lake is a room. "We're rowing through a lake that looks fairly poisonous. It's dark purple and filled with trash and garbage. The mist is so thick that I can't see more than a few yards in front of the boat. Today's forecast: not good[first time].[br]I am in deep yoghurt. There's really nothing I can do here[only]."

Report looking in Poison Lake for the first time: bandname 6.

the boat is scenery in Poison Lake. The description of the boat is "This accursed boat that my arms are tied to."

the junk is scenery in Poison Lake. The description of junk is "It's impossible to describe how much junk there is in the water. I spot some umbrellas, clothing, furniture, books, lots of paper, discarded food containers, and televisions." Understand "trash" or "umbrella" or "umbrellas" or "clothing" or "furniture" or "books" or "paper" or "containers" or "television" or "televisions" or "garbage" as junk.

the lake mist is scenery in Poison Lake. The description of lake mist is "The mist is impeding my sight, but more importantly, it's all over my skin. I feel goosebumps."

a slave driver is a man in bsh-boathouse. The description of slave driver is "I look timidly at the slave driver, and he looks back at me with a grimace." Understand "man"or "dude" as slave driver.

Instead of kissing Slave Driver: say "Flattery will get me nowhere."

Instead of attacking Slave Driver: say "I'd love to clobber this guy with my fists, but he does have a knife."

slave driver's mask is worn by slave driver. The description of slave driver's mask is "A gas mask suitable for braving the mist."

Instead of wearing slave driver's mask:

say "I can't wear that[note 204]!";

Instead of swearing obscenely when the current game is Big Creepy House: say "My superego mocks my failures, pushing me to the edge of mental breakdown."

At the time when shitstorm happens:

if the player is in Poison Lake begin;

say "As we drift up to an unfamiliar shoreline, the slave driver climbs over to my side of the boat and binds my arms through a loop. 'No funny business,' he explains helpfully.[p]I stare through the gas mask at my first glimpse of the mainland. There are oak trees here, and mulch and mosses underfoot. It seems somewhat familiar. In fact, it reminds me a little bit of home.[p]Suddenly, I realize--[p]'Hey!' I yell to the slave driver, who's busy lugging the rowboat up the shore. 'You've got the wrong person! I'm nobody's slave--I live over the hill, in the western valley!'[p]He drops the boat and turns around. Thank God, I'm free! Quickly, I try to remember where my town is. I have only fleeting glimpses, but if I can get over the hill... find some clothing, hopefully... maybe I'll see my family there, and I'll remember some more. Freedom is at hand.";

wait for any key;

say "[p]As I'm lost in thought, suddenly the mask is ripped off my face. I look up at the slave driver in horror. 'What are you doing?!' I beg; my hands are still bound.[p]'You remember too much,' he pants. 'Be back later.'[p]He grabs his scimitar and walks into the mist lazily. No! This can't be happening! I kick furiously against the side of the boat, and start to work on the bonds with my hands. I need to get to the top of this hill before I lose it.";

wait for any key;

say "[p]My left hand reaches up to catch part of the knot, and I tug at it. But it's only getting tighter. I start panicking, and my breathing gets faster. I shove my right arm around through the bonds and the boat tips over slightly, tossing my head down and up. I've got to undo the rope... but why?[p]I shake my head a few times and try to recall what I was doing. The mist is getting to me too quickly; it can't have been more than a few minutes, but my mind's getting hazy already. Slave driver's going to come back, right? Why was I trying to escape? I crane my head behind me and look at the strange rowboat I'm sitting in. Something...[p]A brief glimpse of another person in my mind's eye. I've left someone behind.[p]Wait... behind where? Where was I before I was here?";

wait for any key;

say "[p][b]*** Who am I? ***[/b]";

wait for any key;

carry out the escaping activity with Big Creepy House;

deathify 21;

end if;

revolver is a masc thing. Understand "pistol" and "gun" as revolver.

The description of revolver is "This is a gun. I’ve never owned a gun before. Or if I have, I don’t remember it. Anyway, I don’t know if this gun is loaded, and I don’t want to break it by checking[note 150]."

the hisp of revolver is "revólver".

Instead of examining revolver when the current game is not Big Creepy House:

say "[We] [are*] not exactly a firearms expert; they don't work in many of the tunnels, and they really mess with Article 4 of the Spelunker's Code ('violence isn't the answer to this one.') But you know enough to say that this is a snub-nosed revolver, old but not antique, and loaded. Also, slightly scorched and very sooty. Not a great big stopping-power weapon or anything, but not tiny, so probably a .38? It feels much heavier than its size would suggest.";

Shooting it with is an action applying to one thing and one carried thing.

Understand "shoot [something]" as shooting it with.

Understand "shoot [something] with [something]" as shooting it with.

Understand "shoot [something] at [something]" as shooting it with (with nouns reversed).

Rule for supplying a missing second noun while shooting something with:

if the revolver is visible begin;

say "(with [the revolver])";

now the second noun is the revolver;

otherwise;

say "You really need a missile weapon for that.";

end if;

Instead of shooting something with something:

say "[The second noun] isn't a suitable weapon.";

the slave driver carries a scimitar. scimitar is sharp. The description of scimitar is "A fearsome-looking scimitar."

the slave driver's body is a thing. The description of slave driver's body is "The body of an ex-slave driver." Understand "driver" or "dude" or "corpse" as slave driver's body.

Instead of taking the slave driver's body: say "I’d rather not lug that around with me, thank you."

Instead of shooting something with the revolver:

if the current game is:

-- Mountains of Ket: say "Guns don't work in cod-fantasy.";

-- Sweet Sixteen: say "That'd be... unwise, given the gun-toting Castle Doctrine maniac lurking at the story's edges.";

-- Big Creepy House: say "I'm not interested in target practice.";

-- Dracula: say "La violencia no es la respuesta a esta.";

-- otherwise: say "Violence isn't the answer to this one.";

Instead of shooting the player with the revolver:

if the current game is:

-- Mountains of Ket: say "Guns don't work in cod-fantasy.";

-- Big Creepy House: say "That would be disastrous!";

-- Dracula: say "La violencia no es la respuesta a esta.";

-- otherwise: say "Death's survivable, but that doesn't make it something you'd do for shits and giggles.";

Instead of shooting the slave driver with the revolver:

say "I whip out my gun and make a clean shot[note 151]. The slave driver falls down dead in an instant.[bracket]Your score has just gone up by one point.[close bracket]";

accomplish accomp1;

remove the slave driver from play;

move the slave driver's mask to the location of the player;

move the scimitar to the location of the player;

move the slave driver's body to the location of the player;

[may not work in boat]

Chapter 1 - The Fire Man Go Down Below

The block burning rule is not listed in any rulebook.

Check burning (this is the unburnable man rule):

if the noun is a person begin;

say "What a horrible thought.";

stop the action;

end if;

Check burning (this is the unburnable thing rule):

if the noun is not burnable begin;

say "That's unlikely to provide a decent flame.";

stop the action;

end if;

[maybe a destroyed-by-fire but not useful as a firelight rule]

Check burning a burnable thing (this is the no ignition rule):

if the player carries a lit thing or the player carries the lighter begin;

continue the action;

otherwise;

if the current game is Big Creepy House begin;

say "[We] need something that's burning to set [the noun] on fire.";

otherwise if the current game is Dracula;

say "Necesitas algo que se quema de quemar [the noun].";

otherwise;

say "[We] need a source of fire for that.";

end if;

stop the action;

end if;

Carry out burning a burnable thing:

say "[We] light[-s] [the noun] with [the random lit thing carried by the player].";

now the noun is lit;

Before printing the name of a lit burnable thing (called pyre):

if the current game is not Dracula, say "burning ";

After printing the name of a lit burnable thing (called pyre):

if the current game is Dracula, say " ardiente (que proporciona la luz)";

A thing has a number called burncount. The burncount of a thing is usually 7.

The burncount of wooden box is 5.

A thing is usually unlit.

boxburn is a number that varies. boxburn is 10.

Fireman rules is a rulebook.

This is the mighty fire rule:

if boxburn < 1 begin;

now wooden box is burnable;

end if;

if the brick oven is fiery begin;

if there is an unlit burnable thing in the brick oven begin;

if the player is in bsh-kitchen, say "Flames emanating from the burning brick oven engulf [the list of unlit burnable things in the brick oven].";

repeat with Z running through unlit burnable things in the brick oven begin;

now Z is lit;

end repeat;

end if;

end if;

The mighty fire rule is listed first in the fireman rulebook.

A fireman rule:

if the wooden box is in the brick oven and the brick oven is fiery and the wooden box is unlit begin;

now boxburn is boxburn - 1;

if the wooden box is visible, say "The wooden box is getting warmer.";

end if;

The bookburn count is a number that varies. the bookburn count is 0.

A fireman rule:

repeat with N running through lit burnable things begin;

now the burncount of N is the burncount of N - 1;

if the burncount of N is 1 begin;

if N is visible, say "[The N] [is-are] almost totally aflame!";

otherwise if the burncount of N < 1;

if N is visible, say "[The N] turn[s] to ash[if N is wooden box], leaving a revolver behind[note 148][end if].";

now N is unsafe;

if N is wooden box, move revolver to brick oven;

remove N from play;

if N is a book, now the bookburn count is the bookburn count + 1;

if the bookburn count is 12 begin;

accomplish accomp8;

end if;

end if;

end repeat;

A fireman rule:

if there is a lit burnable thing in the brick oven and the brick oven is chilled begin;

if the player is in bsh-kitchen, say "The brick oven glows with the warmth of [the random lit burnable thing in the brick oven].";

now the brick oven is fiery;

end if;

if there are exactly 0 lit burnable things in the brick oven and the brick oven is fiery begin;

if the player is in bsh-kitchen, say "The burning brick oven has cooled down.";

now the brick oven is chilled;

end if;

Every turn: follow the fireman rules.

Check taking:

if the brick oven encloses the noun and the brick oven is fiery begin;

say "It looks like we’ve got a nice fire going in the burning brick oven. I don’t want to reach inside right now.";

stop the action;

end if;

Part 8 - Take One

[TODO]

Pursuit time is a kind of value. -3:59 specifies a pursuit time.

Take One is a game in startroom. The precis of Take One is "[set link 507][bold type]Take One[roman type][end link] by Robert Street (2005)[line break]

1.5/5 stars".

The description of Take One is "[b]Take One[/b][line break]by Robert Street[line break]2005[p]Development System: ADRIFT[p]* [b]Nuking the fridge made more sense than this game (RR #3)[/b]

by Andy Devil[br]Take One by Robert Street is a very short, very linear game. In fact, even with the walkthrough, you will likely have a hard time beating it if you don't follow it to the word. A pretty unrealistic time counter (even trivialities and failed actions use up time, for example) limits the exploring you will do in this game and pretty much ensures you have to play it again and again to figure it out. Aside from this bad design decision, the syntax is quite picky, which is guaranteed to hamper your abilities of puzzle-solving. Due to its short length, with some patience the game should be beatable though.[p]Compared even to the bad gameplay, the story of Take One isn't a beautiful and unique snowflake either. The premise tells you that you are a film director in command of a Indiana Jones-referencing character, yet the perspective is just like in any other interactive fiction game. Crystals, supernatural beings and the likes are used in pretty stereotypical manner and there isn't even an attempt to make the story or setting different from something that was thought up in five minutes. A particular odd writing quirk is that the stereotypical dumb blonde protagonist is insulted by the movie director (which is you!) in both the very beginning and end of the game, yet there isn't the slightest justification for it anywhere in the game text! [p]Bottom line: Another 'play and forget' game. 2/10[p][co]There are a couple of other reviews, along similar lines.[/co][p][set link 527][b]Open it up.[/b][end link]".

Carry out opening Take One:

clear the screen;

say "[b]TAKE ONE[/b][p]by Robert Street (Rafgon)[p]Filming today begins on your new action movie, 'Indianette Jones and the Orb of One.' First off is one of the film's main action scenes. The actress playing the title character is on set and you can see her through the monitors. You are not sure she is a good fit for the role. She looks great, with her blonde hair and the way she fills out her skimpy explorer outfit, but her acting skills are non-existent. Actually, having talked to her, her intelligence is also non-existent[lady 4][note 36].[br]You will have to give her directions on the set. It is a simple set of tasks. To open the crystal she will have to read the book aloud and rub the ring. She will then have two and a half minutes to grab the orb and set a trap for the demon. You are not quite sure yourself yet what you want for some of the other details. You never did read the storyline you were given by the studio in much detail[note 37]. You will just have to watch and make it up as you go along. She won't be able to improvise, so you will have to.";

wait for any key;

say "[p]TAKE ONE[p]";

wait for any key;

move the player to t1-passage;

now the player wears ring;

now the player carries whip;

now the player carries journal;

now the story viewpoint is third person feminine;

Instead of examining the player when the current game is Take One: say "Indianette Jones is as well as can be expected, considering the circumstances. Indianette Jones is wearing [a list of things worn by the player].";

Take One has a number called gamecount. The gamecount of Take One is 1.

The demon clock is a pursuit time that varies. The demon clock is 2:40.

To reset Take One:

now the journal is unread;

now the player wears Indy's ring;

now the player carries whip;

now the player carries journal;

remove the orb of one from play;

now the crystal is inactive;

now the crystal is in Ancient Gallery;

now the jewel is part of the broken statue;

now the machine is switched on;

now the cage fixture is closed;

remove the demon from play;

remove the machine from play;

now the demon clock is 2:40;

now the gamecount of Take One is the gamecount of Take One + 1;

now the right hand status line is "[turn count]";

say "[p]TAKE [gamecount of Take One][p]";

wait for any key;

now the player is in t1-passage;

The saferoom of Take One is t1-passage.

the Indy's ring is a wearable valuable masc tiny thing. The description of Indy's ring is "The ring is a simple band of gold. It appears ordinary but there is more to it than meets the eye. When rubbed, after the passage from the journal is read aloud, it will open the crystal." The printed name of Indy's ring is "gold ring".

The hisp of Indy's ring is "anillo". Understand "anillo" or "gold" as Indy's ring.

The epilogue of Indy's ring is "a worthless prop, possibly worth a few quid if you get a dwarf to inscribe it and flog it at a con".

To say orbwhine:

say "[one of][or][note 46][or][stopping]";

To say indywhine:

say "[one of][or][or][or][or][note 49][or][or][note 50][or][or][or][note 51][or][stopping]";

the journal is a masc burnable thing. The description of journal is "The journal is an ancient, leather-bound book, dusty with the passing years. It is almost too fragile to touch without damaging in some way. According to the plot of the movie, it tells the story of the [if current game is Take One]orb of one[orbwhine][otherwise]Orb of One[end if]. When a certain passage from it is read aloud it starts the process of opening the crystal. The orb of one can then be taken, although the demon also trapped within the crystal will soon chase down anyone who releases it and steals the orb."

The hisp of journal is "diario de Indianette". Understand "diario" or "diario del Indianette" or "book" as journal.

Instead of examining the journal when the current game is Take One:

say "Indianette Jones[first time][indywhine][only] can examine the journal, but there is no need to read it aloud here.";

Instead of rubbing the ring when the current game is Take One:

say "Indianette Jones[first time][indywhine][only] does not need to rub the ring here.";

the whip is a masc thing. The description of whip is "The whip looks almost like a fashion accessory[note 43] for Indianette Jones, but it is also functional if necessary."

The hisp of whip is "látigo". Understand "latigo" as whip.

Movie Set is a region.

t1-passage is a room. The printed name of t1-passage is "Passage (on screen 1)".

The description of t1-passage is "The broken bones of tiny rodents crunch underfoot as Indianette[note 38] Jones makes her[note 90] way along the passage. It is dark and shadowy for the most part, illuminated poorly by the pale daylight at the end.[p]The passage extends northeast to the outside world and southwest to an ancient gallery."

t1-passage is in Movie Set.

Indianette Jones is a woman in t1-passage. "Indianette Jones[first time][indywhine][only] is [if the crystal is active]all ready to get moving in this chase scene, but she is waiting for her next order[otherwise]standing around, looking bored and waiting for her next order[end if]." The description of Indianette Jones is "Indianette Jones is the actress that was chosen by the studio for this film[note 39]. She looks the part, but doesn't act it."

Instead of examining the player when the current game is Take One: say "You are the director of this film, and you are sure that it is going to be a success[note 45]."

Before looking when the current game is Take One:

now Indianette Jones is in the location of the player;

Instead of going northeast in t1-passage: say "Indianette Jones[first time][indywhine][only] begins to move offstage, but is ordered back on[note 137], as the filming is not finished yet.";

the broken bones are scenery in t1-passage. The description of broken bones is "These bones are not real. Animal rights groups would cause too much of a fuss if these effects were created in an authentic manner."

Ancient Gallery is southwest of t1-passage. "The walls about Indianette Jones[first time][indywhine][only] are ancient and crumbling, yet modern looking portraits hang from them all the same. The faces depicted twist and writhe in torment. It is almost possible to [i]hear[/i] their cries and imagine that it is a warning for anyone wishing to open up the crystal. Against one wall lies a large crystal, as tall as a man and wide as a chariot, in which is imprisoned the form of... something.[p]A passage leads away to the south and another to the northeast, at the end of which a light shines faintly." The printed name of Ancient Gallery is "Ancient Gallery (on screen 2)".

Ancient Gallery is in Movie Set.

some portraits are scenery in Ancient Gallery. The description of portraits is "The portraits look too modern, which was probably a mistake by set design. Still, the paintings fit the mood." Understand "portrait/painting/paintings" as portraits.

the large crystal is scenery in Ancient Gallery. The description of large crystal is "The large crystal has a blackness inside of it. This is where the orb of one[orbwhine] is trapped, but there is also a demon inside the crystal to protect the orb. In reality it is only a digital construct on the screen, and Indianette Jones[first time][indywhine][only] has to pretend that there is something there[note 44]."

The crystal can be active or inactive. The crystal is inactive.

The journal can be unread or read. The journal is unread.

Instead of examining the journal in Ancient Gallery:

say "Indianette Jones[first time][indywhine][only] flicks through the journal until she comes to the right passage. She then begins intoning the spell. It is some ancient language, but it really just sounds like gibberish. It could just be the way she is pronouncing it though. The journal crumbles into dust after Indianette Jones[first time][indywhine][only] is finished. Now all that is left is to rub the ring.";

remove journal from play;

now journal is read;

Instead of examining a book in Ancient Gallery when journal is unread:

if the noun is:

-- Almagest:

say "Indianette clears her throat. 'And therefore meditating that the other two genera of the theoretical would be expounded in terms of conjecture rather than in terms of scientific understanding: the theological because it is in no way phenomenal and attainable, but the physical because...'[p]'Cut, cut,' you lament. 'Wrong book.'";

-- Didache:

say "Indianette flicks through the book for an appropriate passage. 'Τέκνον μου, φεῦγε ἀπὸ παντὸς πονηροῦ καὶ ἀπὸ παντὸς ὁμοίου αὐτου. μὴ γίνου ὀργίλος, ὁδηγεῖ γὰρ ἡ ὀργὴ πρὸς τὸν φόνον, μηδὲ ζηλωτὴς μηδὲ ἐπιστικὸς μηδὲ θυμικός· ἐκ γὰρ τούτων ἁπάντων φόνοι γεννῶνται...'[p]'Stop that,' you snap, 'I vaguely remember some ill-declined Latin being in the script about here. You know, magic.'[p]'I don't [i]speak[/i] Latin,' points out Indianette, 'and this flows a lot more -'[p]'Stick with the script, missy. Action!'";

-- Talmud:

say "Indianette drops the book open somewhere near the beginning and recites. 'Said R. A'ha bar Abayi to Rabhina: What does the questioner mean? Unintentionally and without remembering (that it is Sabbath), then what does the expression 'allowed' mean? To whom? He is still not aware of it. On the other hand, if he did it unintentionally and afterward he remembered of the Sabbath...'[p]'What is this crap? Just say the damn line.'";

-- Leviathian:

say "Indianette flips to the contents, then to a point near the end of the book. 'Neverthelesse, the contrary Doctrine, namely, that there be Incorporeall Spirits, hath hitherto so prevailed in the Church, that the use of Exorcisme, (that is to say, of ejection of Devills by Conjuration) is thereupon built; and (though rarely and faintly practised) is not yet totally given over. That there were many Daemoniaques in the Primitive Church, and few Mad-men, and other such singular diseases...'[p]'Pardon? I want fancy-sounding gibberish, not... what is that?'[p]'Thomas Hobbes, arguing that demonology is a scriptural misreading and demons are imaginary, the fruit of superstition and ignorance.'[p]'Look, miss, there's a demon in this movie whether you like it or not. Quit stalling and follow the script.'";

-- Metamorphoses:

say "Indianette turns towards the camera, strikes a lyrical pose with one hand upturned and extended, the book propped at her hip, and declaims.[p][i]'Of bodies changed to other shapes I sing.[br]Assist, you Gods (from you these changes spring)[br]And, from the World's first fabric to these times,[br]Deduce my never-discontinued Rhymes...'[/i][p]'CUT. That magic mumbo-jumbo was written by real screenwriters. Stop acting as if you know better than them,' you growl.[p]'Five years at the RSC and this is what I get?' mutters Indianette, returning to her spot.";

-- City of God:

say "Indianette reads. 'Ahem. That the contrary propensities of good and bad angels have arisen, not from a difference in their nature and origin, since God, the good Author and Creator of all essences, created them both, but from a difference in their wills and desires, it is impossible to doubt. While some steadfastly...'[p]'CUT. Really? What is this?'[p]'I don't know, maybe I thought that a brief divergence into Early Church demonology might inject some substance into this wreck of a script?'[p]'It wouldn't. Places, everyone.'";

-- Colliget:

say "Indianette Jones apparently can't read Arabic. Why didn't you hire a method actor?";

-- Symposium:

say "Indianette cracks her neck, shifts her feet around, and assumes the body language of a stand-up comedian. 'Alright, that shit you wanted? I got it. So a couple days back I was headed downtown when I run into one of my girls, and she's all, I heard you were at Agathon's when Socrates and his crew were talking shit about love and all that, so spill. Now, tell the truth, I wasn't there, I had it from Aristodemus - little guy, no shoes -, and reading between the lines I figure he got pretty messed up at said party, so we have what might charitably be described as a through-a-glass-darkly situation here. But I still figure, why spoil a good story with the facts, right? So we're walking...'[p]'You want to be looking for work? No? Get back to the script.'";

-- Iliad:

say "Indianette declaims:[p][i]Rage-Goddess, sing the rage of Peleus['] son Achilles,[br]murderous, doomed, that cost the Achaeans countless losses,[br]hurling down to the House of Death so many sturdy souls…[/i][p]'Cut! What translation even [i]is[/i] that crap?'[p]'Fagles. You should be glad I didn't go with [i]All Day Permanent Red[/i].'[p]'That'll be quite enough of that. PLACES.'";

-- Life of Cuthbert:

say "Indianette quickly skims through the index and flips to a page. 'Whilst they were going, the man began to cry, and the tears ran down his cheeks, for he was afraid lest Cuthbert, finding her afflicted with a devil, should think that she had been a false servant of the Lord, and that her faith was not real. The man of God consoled him...'[p]'Read on your own time! When I'm paying you, read your damn lines.'[p]'I'm just not entirely comfortable with dealing with a creature that's basically a Christian-animism idea of a seizure spirit,' says Indianette.[p]'If you wanted comfortable, why'd you get into movies? Back in line.'";

-- Aeneid:

say "[i]Arma virumque cano, Troiae qui primus ab oris[br]Italiam, fato profugus, Laviniaque venit[br]litora, multum ille et terris iactatus et alto[/i][p]'Pardon? What the shit is that?'[p]'Well, I thought that as long as we were reciting Latin on the assumption that nobody understands it, we might as well put in a gag for the people who [i]do[/i] speak Latin and flinch every time -'[p]'I don't tolerate deviations from the script. You're not the artist here, you're a warm body with vocal chords. Do your job.'";

Instead of examining Bottle Manuscript in Ancient Gallery when journal is unread:

say "Indianette flips to a random page. '[i]In between the inner and outer walls are thousands of bird skeletons, an eerie sight which Governor is at a loss to explain. The guards must clear the paths they use every week because birds seem to drop out of the sky and die here.[/i]'[p]'Cut! God, there's nothing I loathe more than actors who try to sneak in their inevitably terrible attempts at writing.'[p]'It's not mine,' protests Indianette. 'I just... there was a mix-up with the scripts, somehow? Let's take it from my entrance.'"

Instead of examining unlocked diary in Ancient Gallery when journal is unread:

say "Indianette begins reading. 'June 1st, 1984. [i]Temple of Doom[/i] was the worst. So so stupid, and who cares about Harrison Ford any more anyhow, but it's an excuse. Tried to talk Heather into letting me sleep over afterwards, but her grandparents -'[p]'CUT. What possible fucking relevance has this to this, or any movie?'[p]Indianette has clearly been preparing a small speech here. 'Look, we all know that the studio's pulling the plug anyway if we don't turn this around, and I think that we can repurpose some of the material here. So the protagonist is a young woman struggling with a family legacy of sexual abuse, via a quest through liminally-fantastic dreamworlds, initially derived from mid-80s pop culture, only over the course of the - look, I've spoken to some people over at the Creature Shop who would give their left nut to tackle some serious adult material -'[p]'And that is why actresses aren't paid to think. I suppose at the end she reclaims her sexuality? Just say the damn lines.'";

the orb of one is a valuable thing. The description of the orb of one is "[if the current game is Take One]This spherical orb looks like a valuable piece of jewellery. It is also supposed to have some mystical powers as well, but this scene is too early in the film to reveal them[otherwise]A snowglobe-sized, opalescent sphere, quite heavy. Fire glitters in its milky depths[end if]."

The indefinite article of the orb of one is "the".

The epilogue of the orb of one is "which is an obvious plot coupon, and thus covers four weeks of utilities rather than two".

After taking the orb of one: say "Taken[note 165]."

Rule for printing the name of the orb of one when the current game is not Take One and the current game is not Dracula: say "Orb of One".

The hisp of orb is "el Orbe de Una". Understand "orbe" or "una" or "orbe de una" as orb.

the orb of one is hisp-proper.

Instead of waiting when the current game is Take One: say "Time passes..."

Instead of rubbing the ring in Ancient Gallery when the journal is read:

say "Indianette Jones[first time][indywhine][only] rubs the ring vigorously. Nothing happens for a few seconds until a few drips start to appear on the outside of the crystal. Soon these drips multiply, as the crystal dissolves into a puddle on the floor. The puddle starts to evaporate, revealing the orb of one[orbwhine]. However, the evaporating black steam from the puddle is beginning to take a physical form. This is the demon, who will kill whoever released him and eat the orb after becoming fully formed. He should appear again in about two and a half minutes[note 47].";

remove the crystal from play;

now the crystal is active;

move the orb of one to Ancient Gallery;

now the right hand status line is "TIME LEFT: [the demon clock]";

Instead of rubbing the ring in the Ancient Gallery when the journal is not read and the current game is Take One:

say "It is not time to rub the ring yet.";

Instead of rubbing the ring in Ancient Gallery when the journal is read and the crystal is active:

say "Indianette Jones[first time][indywhine][only] has already rubbed the ring.";

Every turn when the current game is Take One and the crystal is active:

now the demon clock is the demon clock - 0:10;

if the demon clock is 0:00 begin;

say "The demon lets out a scream, as it suddenly emerges somewhere behind Indianette Jones[first time][indywhine][only].[run paragraph on]";

if the player can see the jewel and the player can see the orb begin;

say " It rushes into the [location of the player] and looks hungrily at both the orb and jewel, almost seeming to be confused over which is which. Unfortunately, no trap has been set and Indianette Jones[first time][indywhine][only]is standing too close to the demon to escape. As a digital construct the demon has no physical presence and cannot actually hurt Indianette Jones[first time][indywhine][only]. However, it does mean that this take is a failure and you will have to start again.";

deathify 7;

wait for any key;

reset Take One;

otherwise if the jewel is not visible;

say " It moves towards Indianette Jones, but then pauses momentarily. A horrible crunching sound can be heard, with the demon eating something[note 131].";

now demon is in the location of the jewel;

if jewel is in cage fixture and cage fixture is closed, now demon is in cage room;

remove the jewel from play;

end if;

end if;

if the demon clock is -0:10 begin;

now the right hand status line is "[turn count]";

if the demon is not in the cage fixture or the cage fixture is not closed begin;

if the player wears mages cloak begin;

say "The demon rushes into the humming chamber and looks hungrily at the orb. Unfortunately, no trap has been set and Indianette Jones is standing too close to the demon to escape.[p]Indianette spins around, the wizard cloak forming a dramatic swirl, and holds up two fingers in a kung-fu pose. 'Fortified Banishment!'[p]There's momentary silence on set. Then the producer pipes up with 'C'mon, no way she's got the spell levels for that.'[p]'Well, yeah, it'd make nonsense of the threat if I could've done that all along. But we've all got to get through this somehow, right?' There is a small chorus of sympathetic groans from around the set.[p]Sigh. Evidently you're the only one with the slightest sense of professionalism. 'All, right, you've had your little fun, Indianette or whatever. Let's stick to the script next time, shall we? If you've even read it? Places, everyone.'";

wait for any key;

reset Take One;

otherwise;

say "The demon rushes into the humming chamber and looks hungrily at the orb. Unfortunately, no trap has been set and Indianette Jones is standing too close to the demon to escape. As a digital construct the demon has no physical presence and cannot actually hurt Indianette Jones[first time][indywhine][only]. However, it does mean that this take is a failure and you will have to start again.";

deathify 7;

wait for any key;

reset Take One;

end if;

end if;

end if;

Instead of going south in Ancient Gallery when the player does not carry the orb:

say "Indianette Jones[first time][indywhine][only] needs the orb of one[orbwhine] first, before the chase begins.";

Ruined Statue is south of Ancient Gallery. "Above Indianette Jones[first time][indywhine][only] towers a broken statue, ravaged by the passage of time. A crown of stone rests upon its brow, a glittering spherical jewel its centrepiece. About the actress lurks malevolent shadows, seeming to move with a life of their own, although this is an illusion that vanishes the moment anyone looks closely at them.[p]Passages in the ruined walls of this place lie to the north and west." The printed name of Ruined Statue is "Ruined Statue (on screen 3)". Ruined Statue is in Movie Set.

the shadows are scenery in Ruined Statue. The description of shadows is "The lighting effects have created a very eerie atmosphere in this room."

the crown is scenery in Ruined Statue. The description of crown is "The crown of stone is worn by the statue. It would be a little too heavy for Indianette Jones[indywhine] to wear."

the broken statue is scenery in Ruined Statue. The description of broken statue is "The statue looks old and decayed, although it was only made last week."

a spherical jewel is part of broken statue. The description of spherical jewel is "The jewel is a similar size and shape to the orb of one,[orbwhine] but it is not nearly as valuable."

The jewel can be pinged. The jewel is not pinged. Instead of dropping jewel when the current game is Take One: say "Just moving the jewel from the statue to the floor seems like a waste of energy."

Instead of taking spherical jewel when spherical jewel is part of broken statue:

say "Indianette Jones[indywhine] cannot just take the jewel from where she is standing[note 209].";

Using it on is an action applying to one thing and one thing. Understand "use [something] on [something]" as using it on. Understand "use [something] with [something]" as using it on.

Instead of using the whip on the spherical jewel:

if the jewel is part of the broken statue begin;

say "Indianette Jones cracks her whip at the jewel and misses. The second time she also misses, but on the third time the jewel is hit and it comes tumbling down into the arms of Indianette Jones[first time][indywhine][only].";

now the jewel is pinged;

now the player carries the spherical jewel;

otherwise;

say "I don't understand what you mean!";

end if;

Instead of using the whip on the crown when the jewel is part of the broken statue:

say "I don't understand what you want me to do with the whip.[p][co]Oh, for heaven's sake. Here, let me fix that.[/co][p]";

try using the whip on the spherical jewel;

Instead of using something (called foo) on something:

say "I don't understand what you want me to do with [the foo][if the jewel is pinged][note 48][end if].";

Cage Room is west of Ruined Statue. "[if cage fixture is closed]At the centre of this circular chamber is a cage, sunken into the floor, in which the remains of some beast lie decomposing. Claw marks on the bars of the cage indicate the beast fought ferociously to escape its imprisonment, yet failed. And died. The bars of the cage reach from the floor to the ceiling. Indianette Jones[first time][indywhine][only] can just fit through the thin path around the side of the cage.[otherwise]There is no sign of the cage that was previously in this location, apart from a sunken depression in the centre of the floor. The bars have fully retracted, following your use of the machine in the adjoining room. The remains of some beast still lie decomposing inside the depression. The beast has finally been freed, although it is a little late, as it has already died. Despite its best efforts, it could not escape the now hidden cage.[end if][p]To the west there is a large chamber from which a humming sound emanates; to the east there is a statue." The printed name of Cage Room is "Cage (on screen 4)".

Cage Room is in Movie Set.

the cage fixture is scenery in Cage Room. cage fixture is a closed transparent container. The printed name of cage fixture is "[if closed]cage[otherwise]depression[end if]". The description of cage fixture is "[if closed]The bars of the cage surround a depression in the centre of the floor of this room. The cage extends from the floor right up to the ceiling. Anyone or anything trapped in this cage is not going to escape easily. The cage was built by professionals and could be used as an actual prison. If anyone plays up on set, they're headed for the cage[otherwise]The cage has been retracted and is not visible at present[end if]." Understand "depression" as cage fixture.

the decomposing beast remains are scenery in Cage Room. The description of beast remains is "The remains of a beast are in the depression. It is difficult to tell what the beast was, mainly because there is no equivalent in the real world. It was designed by one of the artists on the crew. It is lucky it is not real, as the smell would be terrible otherwise."

Instead of inserting something into cage fixture: say "It is not a good idea to put that in the depression."

Instead of inserting jewel into cage fixture:

say "Indianette Jones[first time][indywhine][only] throws the jewel through the cage bars into the depression.";

now jewel is in cage fixture;

Instead of taking something in cage fixture:

say "The cage bars are in the way of Indianette Jones[first time][indywhine][only].";

Instead of inserting orb of one into cage fixture:

say "Without the orb, the rest of the film cannot take place.";

Instead of dropping the orb of one when the current game is Take One:

say "Without the orb, the rest of the film cannot take place.";

Humming Chamber is west of Cage Room. "Once this was doubtless some kind of meeting hall. Rows of seats spiral outwards from a central podium where a speaker once stood to deliver speeches to a waiting audience. Many of the seats are smashed and little but splinters remain. Burn marks scar the foor and walls; in one place there is what appears to be a large quantity of books and scrolls that someone has attempted to burn but abandoned partway through. A faded tapestry is hanging on the section of wall furthest from the entrances. A faint humming [if the machine is in Humming Chamber]noise comes from the machine that has been revealed by moving the tapestry slightly[otherwise]sound can be heard, emanating from somewhere in the chamber. It sounds like there is a machine operating in here[end if].[p]A passage extends northwest and another to the east." Humming Room is in Movie Set.

Instead of going northwest in Humming Chamber when the demon is not in the cage fixture or the cage fixture is not closed:

say "Indianette Jones[first time][indywhine][only] needs to trap the demon before she can progress.";

the tapestry is scenery in Humming Chamber. The description of tapestry is "The tapestry displays a devil-like creature in a cage, with a group of people dancing around it excitedly[note 52]."

the podium is scenery in Humming Chamber. The description of podium is "The podium is the main feature situated in the centre of this room. It is one of the few objects that has survived the destruction."

Understand "look behind [something]" as searching.

Instead of searching tapestry:

say "Indianette Jones[first time][indywhine][only] moves the tapestry to reveal a machine.";

now the machine is in Humming Chamber;

Instead of pushing tapestry: try searching tapestry.

Instead of searching tapestry when machine is in Humming Chamber: try examining tapestry.

demon is a person.

the machine is a device. It is fixed in place and scenery. the machine is switched on.

The description of machine is "The machine is the source of the humming noise. There isn't much to it, apart from a big switch on the side, which is currently in the [if machine is switched on]on[otherwise]off[end if] position."

Carry out examining (this is the examine devices sensibly rule):

if the noun is a device and the noun is not the machine begin;

abide by the examine devices rule;

end if;

Carry out switching off the machine:

now cage fixture is open;

Carry out switching on the machine:

now cage fixture is closed;

Instead of switching on the machine when machine is switched off and demon is in the cage fixture:

say "As Indianette Jones[first time][indywhine][only] turns the switch on, a creaking noise can be heard to the east. Soon a scream of rage can be heard, with something then thumping against metal several times before giving up.";

now cage fixture is closed;

now machine is switched on;

After switching on the machine: say "As Indianette Jones[first time][indywhine][only] turns the switch on, a creaking noise can be heard to the east."

After switching off the machine: say "As Indianette Jones[first time][indywhine][only] turns the switch off, a creaking noise can be heard to the east."

Instead of going east in Humming Chamber when the demon is in the cage fixture and the cage fixture is closed:

say "The demon may be trapped, but he is still dangerous, so it is best not to walk back near the cage.";

Instead of going east in Humming Chamber when the demon is in Cage Room: say "The demon is back there, so it is not a good idea."

Blocked Passage is northwest of Humming Chamber. It is in Movie Set. "The ceiling has collapsed, blocking further access along this passage. On one wall is an opening that overlooks the outside world, with a window of a nearby building almost within jumping distance, but not quite. Unfortunately, the drop looks formidable and difficult to survive, so it is not a good idea to experiment. A roof overhangs the gap, with a horizontal beam that is supporting it also not quite within reach.[p]The passage leads back to the southeast."

Instead of jumping in Blocked Passage: say "It is too far for Indianette Jones to jump or climb down.";

Instead of going down in Blocked Passage: say "It is too far for Indianette Jones to jump or climb down.";

the beam is scenery in Blocked Passage. The description of the beam is "The beam on this roof has been specially made to be a little sticky. The beam is out of reach for Indianette Jones to reach with her hands."

Instead of using the whip on the beam:

say "Indianette Jones[first time][indywhine][only] swings the end of her whip towards the beam, which it wraps around. Holding tightly to the whip she then swings across the gap straight through the window of the other building. She has escaped the demon and carried off the orb of one, but the action in the movie is not over yet. It is over for now though.[br]Finally this scene is finished and it only took [the gamecount of Take One] takes. You've had enough for one day. Maybe it will go better tomorrow, but you have the feeling that this is going to be a long process, especially with all the editing that will probably be needed. You are going to be very tired soon if you have to keep specifically ordering the actress around as well as your other duties.[br]Why are good[note 53] actresses so expensive?";

wait for any key;

carry out the concluding activity with Take One;

Instead of jumping in Blocked Passage when the player is springy:

say "[co]Indy steps back a little, then abruptly sprints at the gap and launches herself at the window opposite. It's an impossible distance, but somehow she soars across the open space and plunges through the window without so much as brushing the sides.[/co][br]She has escaped the demon and carried off the orb of one, but the action in the movie is not over yet. It is over for now though.[br]Finally this scene is finished and it only took [the gamecount of Take One] takes. You've had enough for one day. Maybe it will go better tomorrow, but you have the feeling that this is going to be a long process, especially with all the editing that will probably be needed. You are going to be very tired soon if you have to keep specifically ordering the actress around as well as your other duties.[br]Why are good[note 53] actresses so expensive?";

wait for any key;

carry out the concluding activity with Take One;

the ceiling is a backdrop in Movie Set. The description of ceiling is "The ceiling is not in great condition, as the idea was that this scene took place in ruins."

the walls are a backdrop in Movie Set. The description of walls is "The walls are not in great condition, as the idea was that this scene took place in ruins."

Part 9 - The Snowman

The Snowman is a game in startroom. The precis of The Snowman is "[set link 508][bold type]The Snowman[roman type][end link] by Caio Miranda (2007)".

The description of The Snowman is "[b]The Snowman[/b][line break]by Caio Miranda[line break]2007[p]Development System: Inform 7[br]Forgiveness Rating: Polite[p][b]Renga in Blue[/b][br]The structural motif here is non-linearity. Rather than setting up a discrete set of puzzles, the author has placed in some characters and items and let things run loose. Most interesting is that the author nearly achieves emergent gameplay, and because of this the game is worth a look.[p][co]A little further investigation reveals that this came a close second to [/i]Snowblind Aces[i] in the Text the Halls TIGSource competition. Hunh.[/co][p][set link 528][b]Open it up.[/b][end link]".

Carry out opening The Snowman:

say "Dead link. A little poking around on TIGS reveals a Mediafire link, also dead. No further evidence of ever having lived elsewhere. [frustration][br]You were looking forwards to this one, too.";

carry out the concluding activity with The Snowman;

Part 10 - ARGH's Great Escape

ARGH's Great Escape is an unentitled game in startroom. The precis of ARGH's is "[set link 509][b]ARGH's Great Escape[/b][end link] by Dana Crane[note 121] (2004)".

The description of ARGH's is "[b]ARGH's Great Escape[/b] by Dana Crane[line break]Humor[br]2004[p]Development System: ADRIFT[p][co]No ratings, no reviews. Took part in the... Adrift competition 2004? Okay, ifwiki says that it was actually the ADRIFT 4th One Hour Comp 2004, where it placed second of sixteen.[first time] Gosh, a [/i]ranked[i] speed-IF? A ranked [/i]one-hour[i] speed-IF? That sounds kind of brutal.[only][p]Appears on one list:[/co] Games with stupid characters: 'The title character is stupid, if I recall correctly. I don't think it affects gameplay much, though. (It's been some time since I last played it.)' --David Welbourn.[p][set link 529][b]Open it up[/b][end link]."

Understand "argh" as ARGH's.

Carry out opening ARGH's:

clear the screen;

say "ow jesus fuck my *retinas* dammit fucking ADRIFT default colours KILL IT";

wait for any key;

say "[p][b]ARGH's Great Escape[/b][p]You are ARGH. Proud caveman, aspiring inventor. You were recently jailed in Boulder Rock prison for your attempt to invent a circular device intended on making the moving of objects easier. While you had supporters, all kept quite out of fear of being placed in Boulder Rock; where no man ever leaves.[br]You know if you can escape this place and show everyone what your invention can do, that it would change the world and ease the work of every other caveman on earth.";

now the player is in caveman cell;

beavers invade in two turns from now;

caveman cell is a room. "This is your cell, where you are doomed to spend the rest of your days because of your wild ideas. There isn't much for comfort here, and you didn't expect there would be. Bamboo rods keep you imprisoned in the small cave. A small hole, the size of a large dinosaur egg is located at the top of the cave. Unfortunately is much too high for you to reach, and too small for you to fit through."

The saferoom of ARGH's is caveman cell.

a drumstick is a thing in caveman cell. The description of drumstick is "It is a drumstick from a turkiosaur[note 122]. There is no telling how long it has been here, but it still has meat on it."

The hisp of drumstick is "pierna de guajalotesaurio". Understand "pierna" or "guajalotesaurio" as drumstick.

Instead of eating drumstick when the current game is ARGH's:

say "You bring the drumstick up to your mouth, and are instantly positive that it is rancid. But you're very hungry so eat it anyway, and become very sick. You are rushed off to the infirmary to be cared for. Unfortuantely you have such an extreme case of food poisoning, there was nothing they could do.";

wait for any key;

deathify 20;

now drumstick is in caveman cell;

carry out the escaping activity with ARGH's;

Instead of eating drumstick: say "[co]Right, because food poisoning is exactly what you need right now.[/co]"

At the time when beavers invade:

if the player is in caveman cell begin;

say "Something from above catches your attention. A beaver falls through the hole in the top of the cave. He looks very hungry, and is looking at you intently.";

bandname 7;

now beaver is in caveman cell;

end if;

a beaver is a masc animal. beaver can be well or sick. beaver is well. The description of beaver is "[if well]The beaver is pacing around the cave, looking at you with hungry[note 123] eyes[otherwise]The beaver is looking very sick. It isn't moving, but you are sure it is still alive[end if]."

Instead of riding the beaver: say "You like to ride the beaver as much as the next girl, but now really isn't the time[note 200].";

the fangs are part of beaver. fangs are an unimplement.

The initial appearance of the beaver is "[if well]The beaver is circling around you, mashing his fangs[otherwise]Also here is a beaver[end if]."

Rule for printing the name of sick beaver: say "sick beaver".

The hisp of sick beaver is "castor enfermo". Understand "castor" or "enfermo" as sick beaver.

bamboo rods are a scenery thing in caveman cell.

The description of bamboo rods is "The rods are well built, and no caveman has ever escaped the Boulder Rock Prison. It lies to the south."

Instead of attacking bamboo rods:

if the player carries a sharp thing begin;

let blade be a random sharp thing carried by the player;

if the player is in caveman cell begin;

say "Your [blade] would do the trick nicely, but the guards are too attentive here. Maybe if you could reach some other part of the prison.";

otherwise;

say "You swing [the blade] at the bamboo rods. Though sturdy, they were never intended to cope with steel blades, and you chop your way out in short order.";

wait for any key;

carry out the concluding activity with ARGH's;

end if;

otherwise;

say "A guard comes in from out of nowhere and hits you over the head with a club.[br]'ARGH! No leave! No Noise!'[p]With your head spinning, you watch as the three guards (at least that is what you see) leave the cave, leaving you alone once again.'";

end if;

bamboo rods can be gnawed or ungnawed. bamboo rods are ungnawed.

hole is scenery in caveman cell. "The hole is about the size of a large dinosaur egg, but far to high for you to reach."

Instead of giving the drumstick to the beaver:

say "You hold the drumstick up to the beaver and are barely able to pull your arm away in time. He eats the drumstick in one bite, then looks to you for more. He leaps out toward you, but drops in midair. He looks to be very sick. He reminds you of the nurse you saw on your way in. Well, her hair, anyway.";

remove the drumstick from play;

now the beaver is sick;

Instead of giving big log to the beaver:

say "The beaver regards the log with the air of a gourmand who, having ordered the steak tartare, is presented with an off-ramp diner side-salad.";

Instead of giving chopped logs to the beaver:

say "The beaver regards the log with the air of a gourmand who, having ordered turducken, is presented with tabbouleh.";

The portapet rule is listed instead of the can't take other people rule in the check taking rules.

This is the portapet rule:

if the noun is guard dog or noun is horse or noun is beaver begin;

continue the action;

otherwise;

abide by the can't take other people rule;

end if;

Instead of going south in caveman cell:

say "A guard comes in from out of nowhere and hits you over the head with a club.[p]'ARGH! No leave! No Noise!'[p]With your head spinning, you watch as the three guards (at least that is what you see) leave the cave, leaving you alone once again.";

Instead of taking beaver:

if the player wears mages cloak begin;

say "You pick up the sick beaver. You suddenly get an idea. You throw yourself on the ground and start screaming. The guard quickly rushes in and notices that the drumstick is gone, the beaver is ailing, and you're dressed like a Disney wizard.[p]'Sorceror! Witchcraft!' he roars. If you thought the legal system here was intolerant of technical innovation, it was only because you hadn't seen how they deal with black magic. Spoiler: it involves large rocks. You die as you lived: ahistorically.";

wait for any key;

carry out the escaping activity with Great Escape;

deathify 23;

otherwise;

if beaver is sick begin;

say "You pick up the sick beaver. You suddenly get an idea. You throw yourself on the ground and start screaming. The guard quickly rushes in and notices that the drumstick is gone. He rushes you to the infirmary where you wait for the nurse to come back on duty.";

now beaver is wearable;

now the player is in infirmary;

now bamboo rods is in infirmary;

now the player carries the beaver;

otherwise;

say "ARGH! You can't pick up the beaver. He looks really angry, and very hungry!";

end if;

end if;

infirmary is a room. "This is the infirmary. Sure, no man ever leaves, but they have to give keep try to keep you alive. There is a cell door, much like the one to your cell, except this one leads to freedom. There is a slab, which the patient is to lie on, and a rock table nearby. A cubby hole in the wall, looks to be some sort of storage space."

the rock table is scenery supporter in infirmary. "The rock is an odd shape, but has a flat surface."

some medicine is on slab. The description of some medicine is "It looks like medication of some sort[note 129]."

medicine is singular-named. The indefinite article of medicine is "some".

The hisp of medicine is "medecina". Understand "medecina" as medicine.

the slab is scenery in infirmary. "The slab is where the sick lie."

the cubby hole is a scenery container in infirmary. "It looks like some sort of storage container."

a nurse dress is a masc outfit in cubby hole. "It is a rather cavegirlish nurse uniform[note 128]."

The hisp of nurse dress is "vestido de enfermera". Understand "vestido" or "enfermera" or "vestido de enfermera" as nurse dress.

Instead of wearing the beaver:

say "You plop the the sick beaver on your head. It looks like you have created the first caveman mullet!";

now the player wears the beaver;

Instead of giving the medicine to the beaver:

if the current game is ARGH's begin;

say "You feed the beaver and bring him back to health. He still isn't feeling so hot, but manages to chew through the bamboo bars, making his escape.";

now bamboo rods are gnawed;

remove the beaver from play;

otherwise;

say "You dose the beaver up with medicine. Feeling instantly better, it bites you and escapes.";

remove beaver from play;

end if;

Instead of going south when bamboo rods are gnawed and the current game is ARGH's:

say "Making sure the coast is clear, you are able to escape the Boulder Rock Prison and are finally able to reveal your invention, which you named the Wheel. You not only become the most famous person in the world, you are also the only caveman to ever escape Boulder Rock Prison. Unfortunately you had a run in with that very same beaver a few years later which ended the life of ARGH. The beaver didn't have it so well either. He became very sick and also died. His fangs were mounted on the outside of Boulder Rock Prison in your honor.";

carry out the concluding activity with ARGH's Great Escape;