IFDB Spelunking 2 — 6 of 18

Part 3 - Library Messages

To decide which snippet is what was misunderstood:

(- (((wn - 1) * 100) + (WordCount() - 2)) -) .

To decide which snippet is the misunderstood word:

(- (((wn - 1) * 100) + 1) -) .

To decide if the misunderstood word is known elsewhere:

(- (wn--, NextWord() ~= 0) -) .

Table of custom library messages (continued)

To say m10:

if the current game is Mountains of Ket or the current game is Take One or the current game is Great Escape begin;

say "[m38]";

otherwise if the current game is Sweet Sixteen;

say "[co]The parser won't even accept input if there's no text entered. Is this a good thing? Discuss.[/co]";

otherwise if the current game is Dracula;

say "¿Perdón?";

otherwise;

say "I beg your pardon?";

end if;

To say take10:

if the current game is Big Creepy House begin;

say "I think about taking [the noun] with me, but it's probably better off where it is.";

otherwise if the current game is Sweet Sixteen;

say "You can't.";

otherwise if the current game is Take One;

say "Indianette Jones[indywhine] can't take [the noun]!";

otherwise if the current game is Dracula;

say "Difícilmente podría llevarme eso.";

otherwise;

say "[That's-They're of the library message object] hardly portable.";

end if;

To say m30:

if the current game is Mountains of Ket begin;

say "I'm sorry, but I don't know what a ['][the misunderstood word]['] is.";

otherwise if the current game is Samhain;

say "Off in the distance, the choir of beautiful yet invisible angels that watches over you constantly-- they gasp. Their leader comforts them. 'It's okay,' he says. 'Sometimes this tactless brute will indeed use the word ['][the misunderstood word]['], but we are mature enough to ignore that.' Then he cuts the cheese, and they all giggle.";

[This works rather imperfectly.]

otherwise if the current game is Sweet Sixteen;

say "You can't.";

otherwise if the current game is Dracula;

say "No veo eso que dices.";

otherwise if the current game is Take One;

say "Indianette Jones sees no such thing.";

otherwise if the current game is Great Escape;

say "You see no such thing.";

otherwise;

say "[We] can't see any such thing.";

end if;

To say m38:

if the current game is Mountains of Ket begin;

say "Sorry, but I don't know how to do that.";

otherwise if the current game is Samhain;

say "[m30]";

otherwise if the current game is Sweet Sixteen;

say "Sorry, I don't understand that.[br]Try some different words.";

otherwise if the current game is Dracula;

say "Lo siento, no entiendo eso. Prueba con otras palabras[note 164].";

otherwise if the current game is Big Creepy House;

say "I didn't understand that sentence.";

otherwise if the current game is Take One;

say "I don't understand what you mean!";

otherwise if the current game is Great Escape;

say "Ooougghh?";

otherwise;

say "That's not a verb I recognise.";

end if;

To say m49:

if the current game is Mountains of Ket begin;

say "I'm sorry, but I don't know what a [']['] is.";

otherwise if the current game is Sweet Sixteen;

say "You can't.";

otherwise if the current game is Dracula;

say "¿Qué tengo que [recap of command]?";

otherwise if the current game is Take One or the current game is Great Escape;

let N be indexed text;

let N be "[recap of command]";

let Q be N in sentence case;

say "[Q] what?";

otherwise;

say "What do you want[if the person asked is not the player] [the person asked][end if] to [recap of command]?";

end if;

To say m59:

if the current game is Mountains of Ket begin;

say "[m38]";

otherwise if the current game is Sweet Sixteen;

say "Sorry, I don't understand that.[br]Try some different words.";

otherwise;

say "You must supply a noun.";

end if;

Xyzzying is an action applying to nothing. Understand "xyzzy" as xyzzying.

Instead of xyzzying:

if the current game is:

-- Mountains of Ket: say "[m38]";

-- Sweet Sixteen: say "[m38]";

-- Big Creepy House: say "[b]At End of Road[/b][br]I am standing at the end of a road before a small brick building. A small stream flows out of the building and down a gully.[p]...Snap out of it, self! This is no time to be daydreaming!";

-- Take One: say "I'm sorry, but XYZZY doesn't do anything special in this game!";

-- Great Escape: say "I'm sorry, but XYZZY doesn't do anything special in this game!";

-- nongame: say "Magic has helped you in the past, but only within games.";

-- otherwise: say "That's not a verb I recognise.";

Instead of jumping:

if the current game is:

-- Mountains of Ket: say "[m38]";

-- Dracula: say "Eso no me ayudará.";

-- Sweet Sixteen: say "[m38]";

-- Big Creepy House: say "I jump on the spot, fruitlessly.";

-- ARGH's: say "Wheee-boinng.";

-- Take One: say "Wheee-boinng.";

-- nongame: say "Jumping is inadvisable when negotiating caves.";

-- otherwise: say "You jump on the spot, fruitlessly.";

Instead of singing:

if the current game is:

-- Mountains of Ket: say "[m38]";

-- Dracula:

say "Canto fatal.";

bandname 1;

-- Sweet Sixteen: say "[m38]";

-- Samhain: say "A singing pumpkin? How cuuuuuute.";

-- Big Creepy House: say "My singing is abominable.";

-- ARGH's: say "You sing a little song.";

-- Take One: say "Indianette Jones[indywhine] sings a little song.";

-- nongame: say "You subvocalise a few tuneless lines. The tunnels eat the echo.";

-- otherwise: say "[m38]";

An unimplement is a kind of thing. An unimplement is scenery.

Instead of doing something with an unimplement:

say "[co]That's unimplemented, it would appear.[/co]";

Instead of doing something when the second noun is an unimplement:

say "[co][The second noun] is unimplemented, it would appear.[/co]";