Invisible Parties — 14 of 31

Book - Using

Using is an action applying to one visible thing. Understand "use [a gift]" as using. Understand "[gift]" as using.

Instead of using warrior in the presence of Becky Baumgartner:

say "Polite time [i]way[/i] over. Clademates aren't allowed to attack one another, but this is absolutely self-defence at this point. You close, feint left, and stab a short front-kick towards her solar plexus. She responds with a bland stare, and fades out of existence moments before the blow lands. You stumble, not dangerously but enough to feel like a prat.[p]Well, of course, they [i]made[/i] this place, naturally they know how to get around it. If they'd wanted to make a battleground - and you're not sure any of them are even gifted in that department - they'd have set one up to suit themselves.";

remove Becky from play;

Instead of attacking Becky: try using warrior.

Check using:

if the puzzlecount is 4 and the location is not an egress begin;

say "The only thing left is to run.";

stop the action;

end if;

Check using:

if the location is doomed begin;

say "There's nothing you can do to save this place. Save your skin.";

end if;

Check using:

if Rivka is in the location and the noun is warrior begin;

say "[one of]'You want to play games? All right, let's fucking play,' you snarl, lunging. Rivka... withdraws. It's a neat little trick, a looking-glass effect where you seem to be traveling towards her at speed, and she seems to remain in place, yet she gets further and further away. Before she disappears entirely, she makes a pass with one hand, which now holds [the rivweapon of location], and tips it in sardonic salute: [i]some other time[/i][or]No point in breaking a sweat if she's unwilling to face you[stopping].";

remove Rivka from play;

stop the action;

end if;

Instead of attacking Rivka: try using warrior.

Check using:

if Jave carries the noun and the location is unchallenging and puzzlecount < 4 begin;

say "[one of]You attempt to signal Jave, and she makes no response whatsoever. You repeat the signal. Nothing. And then - oh, great, she springs up, yelling acknowledgement to someone. And then she traverses out[or]Jave ignores you completely for roughly ten minutes. Then she starts as if stung, whirls around, takes three quick steps and vanishes[or]Right on cue, Jave hurries away[stopping].";

make the lady run;

say weaveloss;

stop the action;

end if;

Check using:

if the location is not a challenging room or Jave is not in the location begin;

repeat through the Table of Unchallenging Responses begin;

if the locus entry is the location and the power entry is the noun begin;

say "[the response entry][br]";

stop the action;

end if;

end repeat;

end if;

Check using:

if Jave is not in the location begin;

say "There's nothing you really need to deal with here. You need to [if Jave is seen]find Jave[otherwise]work out the bounds of this place, see if Jave's really around[end if].";

stop the action;

end if;

Check using:

if the player is not in a challenging party begin;

[We need a message here that progressively clues the player in to how they should approach things.]

say "[one of]Hm, how would that work, exactly? You have an idea or two, but -[p]A moment of confusion. Something's not right with the weave. Jave strides away, intent on something, fading as she goes. You're not sure what just happened[or]You're trying to figure out how to get through to her, when the weave [i]shifts[/i] again. You're more alert to it this time: first the fabric of the place convulses, and then Jave and you kind of flow apart, until she is entirely vanished.[p]No, that makes sense. The weave is anchored by the ways, so it stands to reason it'd be strongest where they connect. Most resistant to subversion. If the point of the thing is to keep you and Jave on opposite sides of the glass, it'll work best here[or]That lurch, and Jave takes off again. You'll have to try in a less stable area, away from the entry points[or]It's not going to work here. You make a token attempt to interact with Jave, and she predictably moves on[stopping].";

make the lady run;

stop the action;

end if;

[Check using:

if the location is not a challenging room begin;

say "You can't figure out how that would apply here.";

stop the action;

end if;

]

Instead of using in an egress:

if Jave is not in the location and the best route from the location of Jave to the location of the player through undestroyed rooms is nothing begin;

if the noun is warrior begin;

say "You're tempted to strike one last blow, just as a fuck-you on the way out. Just one good punch to the stomach, winding her.[p]It's never as satisfying as it is in your imagination, though. ";

otherwise;

say "There's no point. You've failed. All that remains is to get out of here.";

end if;

otherwise if Jave is in the location;

say "No time to mess around. You're still perilously close to the tangle. Maybe once you're further out.";

otherwise;

say "You can't afford to mess around out here. You should [if Jave is seen]get to Jave and see if you can disrupt the tangle[otherwise]see if Jave is inside the tangle[end if].";

end if;