Sam Kabo Ashwell

Volume - New Verbs

Book - Fuck Off You Can't Use These

['But should the vulgar feel dissent,

It's such fun to reimplement.'

This is the first time I have had reasonable occasion to do so. Tsawac is not one to mince words. It took some struggle to refrain from figuring out a regular-expressions way of detecting cusses; the following is just meant to capture expressions of frustration.]

Swearing is an action applying to nothing. Understand "fuck" or "shit" or "bollocks" or "motherfucker" or "damn" or "jesus" or "christ" or "goddamn" or "balls" or "bullshit" as swearing.

Praying is an action applying to nothing. Understand "pray" or "meditate" as praying.

Carry out praying:

say "[one of]Walkers are rarely given to structured religion. A substantial minority adhere, or mostly adhere, to customised versions of the major faiths. Most carry out rituals, invented, borrowed or inherited, in very much the same way that they seek out childhood recipes or favourite books; they tend towards ancestor-worship, symbols of identity, of memory. Your particular set of rituals are for quieter times than this, when you're not being watched[or]This is really a time for cursing, not reverence[stopping].";

Instead of praying when the location is wakeroom and wakeroom is not doomed:

say "A good portion of the mourners are doing so. It feels disrespectful to fake it.";

Report swearing:

if the location of Jave is an egress begin;

say "You've still got a hot little ball of rage going, but... just for now, let's set it aside and not ruin the moment.";

otherwise;

say "You curse [one of]a blue streak[or]at length and with feeling[or]ferociously[or]like a sailor[or]the Rebeccas, the worlds and the ways[or]with venom and vigour[at random][one of], coining some inventive compound words in the process[or] in [if a random chance of 1 in 3 succeeds][randomlang], [randomlang] and [end if][if a random chance of 1 in 4 succeeds][langadj] [end if][randomlang][or][or][or][at random][one of]. You're still pissed off, but you feel a satisfying ownership of your anger[or]. You'll see them thrown out of the clade for this. You'll see them fucking [i]burn[/i][or]. [cussresponse][or]. Got to keep that anger at a steady low burn, where you can make use of it[or]. Seriously, what a bunch of [i]assholes[/i][or][or][at random].";

end if;

To say randomlang:

say "[one of]Xhosa[or]Mandarin[or]Scouse[or]Weegie[or]Cantonese[or]Flemish[or]Welsh[or]Tlingit[or]Navajo[or]Ibo[or]Khoi[or]Haitian Creole[or]Quebecois[or]Sanskrit[or]Hindi[or]Sinhalese[or]Old Church Slavonic[or]Urdu[or]Afrikaans[or]Galician[or]Luo[or]Ainu[or]Persian[or]Magyar[or]Quechua[or]Maori[or]German[or]Yiddish[at random]";

To say langadj:

say "[one of]archaic[or]thickly-accented[or]densely idiomatic[or]pidgin[or]high literary[or]formal[or]an obscure dialect of[at random]";

To say cussresponse:

if Jave is in the location and the location is challenging and the location is not orgy begin;

say "Jave gives you an incomprehending smile[one of]. She doesn't even seem to have grasped your tone of voice[or][stopping]";

otherwise if Reba is in the location;

say "Reba attempts to suppress an amused smile[one of]. It's one of her more becoming expressions, and you've never been sure how much it's consciously so[or][stopping]";

otherwise if Becky is in the location;

say "Becky's look implies that she holds you in much the same regard as a small and ill-favoured child who has just deliberately shat on the rug";

otherwise;

say "Nobody appears to notice";

end if;

Understand "make out with [someone]" as kissing.

[The following dispenses with the infamous 'I only understood you as far as wanting to fuck' error, which, while perhaps descriptive of a number of relationships, does not apply to any depicted in this game.]

Rule for printing a parser error when the latest parser error is only understood as far as error:

let Z be the player's command;

try swearing instead;

otherwise;

continue the activity;

end if;

Rule for printing a parser error when the latest parser error is not a verb I recognise error:

let Z be the player's command;

try swearing instead;

otherwise;

continue the activity;

end if;

Talking to is an action applying to one thing. Understand "talk to [a person]" as talking to. Understand "talk [a person]" as talking to.

Topicing is an action applying to one topic. Understand "a [text]" as topicing.

[One of my pet peeves in IF is when you enter a command - say, TALK TO - and the game replies with 'Use CONVERSE for conversation.' If there's ambiguity, or you need a second noun or whatever, fine - but otherwise, just take the action that the player clearly intends, already.]

Instead of saying yes: try topicing.

Instead of saying no: try topicing.

Instead of topicing:

let N be a person;

if there are two not scenery people in the location begin;

let Z be a random not scenery person in the location that is not the player;

try talking to Z;

otherwise if there are two people in the location;

let Z be a random person in the location that is not the player;

try talking to Z;

otherwise;

say "There's nobody here to talk to.";

end if;

Instead of asking a person about some text: try talking to the noun.

Instead of asking a person for something: try talking to the noun.

After deciding the scope of the player while asking:

repeat with X running through things begin;

place X in scope;

end repeat;

Instead of telling a person about some text: try talking to the noun.

Instead of answering someone that some text: try talking to the noun.

Following is an action applying to one thing. Understand "follow [something]" as following.

Instead of following the player: say "You generally do. The question is to where."

Instead of following a crowd: say "They're not going anywhere. And wherever they would go, you doubt you could follow."

Instead of following a person: say "But [the noun] isn't going anywhere."

Instead of following Jave:

if the location is an egress begin;

try going outside;

otherwise if puzzlecount is 4;

say "She gave you the signal to take the lead. Incident command principle: whoever's in charge stays in charge until the situation's stable - even if there's someone around who might be better at it, changes of command are horribly inefficient. There are exceptions, as always, but they all involve the in-charge being incapable of fulfilling the role. This not being the case, it's all on you.";

otherwise;

try talking to Jave;

end if;

Instead of following shadow Jave: say "You didn't see which way she went."

Following Reba is witchfollowing. Following Rivka is witchfollowing. Following Becky is witchfollowing. Instead of witchfollowing: say "There's no hope of chasing down the Rebeccas in a tangle of their own creation."

Instead of taking a crowd: say "Yeah, you could probably take the whole lot of [']em.";

Instead of taking Jave:

if the location is an unchallenging party begin;

continue the action;

otherwise if the location is an egress;

try kissing Jave;

otherwise if the puzzlecount is 4;

say "Just go. She'll follow.";

otherwise;

say "Oh, if it were that simple.";

end if;

Instead of touching Jave when the location is mutualslump and puzzlecount < 4: try taking Jave.

Instead of taking Jave when the location is mutualslump and puzzlecount < 4:

say "You reach over and give her shoulder a gentle I'm-still-here squeeze. Pause. Then she springs to her feet, stumbly, hair falling across her face; mutters something apologetic that makes it clear she doesn't recognise you; and runs off while you're still struggling for a response.";

make the lady run;

Persuasion rule for asking Jave to try following the player:

if the location is an unchallenging party begin;

try talking to Jave;

otherwise if the location is an egress;

try going outside;

otherwise if the puzzlecount is 4;

say "You trust her to do so.";

otherwise;

try talking to Jave;

end if;

Loosening is an action applying to nothing. Understand "loose" or "loosen" or "loose strings" or "loosen strings" as loosening. Instead of loosening: say "As you're not a weaver, you can't do so directly. You'll have to find other ways to weaken the tangle."

Instead of attacking the tangle-ghost: try loosening.

Singing is an action applying to nothing. Understand "sing" or "hum" as singing.

Understand "yell" or "scream" or "howl" or "shout" as singing when the location is bacchanal.

Carry out singing: say "[the singdesc of location][br]".

Dancing is an action applying to nothing. Understand "dance" as dancing.

Dancing with is an action applying to one thing. Understand "dance with [someone]" as dancing with.

Instead of dancing with: try dancing.

Instead of dancing with Jave when the location is ballroom and ballroom is not doomed: say "You would very much like to, but the dance - or the tangle, more likely - is preventing it. You need to change the order of things."

Instead of dancing with Jave when the location is maying and maying is not doomed: try touching Jave.

Carry out dancing: say "[the dancedesc of location][br]".

Instead of thinking: say "You generally do. Pray, continue.";

Understand "remember" as thinking.

It-remembering is an action applying to a topic. Understand "remember [text]" or "think about [text]" as it-remembering.

Instead of it-remembering: say "Much as you're inclined towards it, this is not a good time for navel-gazing."

Invisible Parties — 12 of 31