Apocalypse Fuel — 15 of 18

Book - Iron Horse

vehicsize is a number that varies. vehicsize is 0.

To nomadcheck:

now vehicsize is 0;

let Z be 0;

if the variety of the current gang is nomads or the variety of the current gang is rovers begin;

now Z is a random number between 1 and 5;

say "They travel ";

otherwise if a random chance of 1 in 4 succeeds begin;

let N be roadgangs;

now Z is a random number between 2 and 5;

if Z is 2, add bikegangs to N;

say "They are [b][pop N][/b], [one of]rolling[or]roaming[or]roving[or]traveling[or]venturing out[or]patrolling[or]fighting[or]going to battle[purely at random] ";

end if;

if Z is 1, say "[pop footways]. ";

if Z is 2, say "[pop bikeways]. ";

if Z is 3, say "[pop carways]. ";

if Z is 4, say "[pop truckways]. ";

if Z is 5, say "[pop mixways]. ";

now vehicsize is Z;

if vehicsize is not 1, say "[exceptionalrig][br]";

To say battlecar:

say "[p]Their [one of]best[or]best-loved[or]most feared[or]weirdest[or]most valuable[or]most useful[or]most striking[or]most customized[purely at random] vehicle is ";

roadgangs is a list of texts that varies. roadgangs is {"highly mobile", "road warriors", "revheads", "a road gang", "riders"}.

bikegangs is a list of texts that varies. bikegangs is {"bikers", "war hogs", "a bike gang", "choppers"}.

footways is a list of texts that varies. footways is {"on foot", "on foot, with a few pack animals", "on foot, sticking to terrain too [one of]rough[or]broken[or]steep[or]wet[or]harsh[or]dangerous[or]overgrown[or]choked[or]unstable[purely at random] for vehicles"}.

bikeways is a list of texts that varies. bikeways is {"on motorbikes", "on tough, agile [one of]dirt-bikes[or]scrambler bikes[or]motocross bikes[or]trail bikes[or]rally bikes[purely at random]", "on fast, dangerous [one of]sports bikes[or]racing bikes[or]crotch rockets[or]streetfighter bikes[or]muscle bikes[purely at random]", "on easy-riding cruiser bikes", "on power cruiser bikes", "on [one of]roadster bikes[or]standard motorbikes[or]naked bikes[purely at random]", "on heavy, capacious [one of]touring[or]bagger[or]dresser[purely at random] bikes", "on cobbled-together rat bikes", "on slow, rugged-terrain [one of]four-wheelers[or]quadbikes[or]ATVs[purely at random]"}.

carways is a list of texts that varies. carways is {"in cars", "in an assortment of cars", "in ex-military [one of]cars[or]jeeps[or]humvees[or]landrovers[purely at random]", "in dune buggies", "in light off-roaders", "in [one of]pick-ups[or]utes[or]flatbeds[purely at random]", "in heavy [one of]SUVs[or]4x4s[purely at random]"}.

truckways is a list of texts that varies. truckways is {"in big rigs", "in heavy trucks", "in a single, vast war-rig", "in all-wheel drive trucks"}.

mixways is a list of texts that varies. mixways is {"in a rag-tag mix of vehicles", "in a [one of]road fleet[or]battle group[or]tarmada[purely at random], with motorcycles and midweight vehicles supporting a heavy [downpop rignouns]"}.

vehiclenames is a list of texts that varies. vehiclenames is {

"[xthe][vehicnoun]",

"[xthe][one of][pop commonnouns][or][pop commonadjs][or][pop basicverbs][or][pop Beasts][purely at random][one of]mobile[or]boy[or]girl[or]ride[or]wagon[or]rider[purely at random]",

"[xthe][pop hardcoreprefs] [vehicnoun]",

"[one of][xthe][pop Rulers] [or][purely at random][pop allbasicnames]",

"[xthe][pop facecards] of [one of][plure][pop commonnouns][s][or][pop suits][purely at random]",

"[xthe][pop commonverbers]"

}.

facecards is a list of texts that varies. facecards is {"Ace", "King", "Queen", "Prince", "Jack", "Lord", "Lad[*ies]", "Duke", "Deuce", "[pop Rulers]"}.

suits is a list of texts that varies. suits is {"Hearts", "Spades", "Diamonds", "Clubs", "Cups", "Swords", "Wands", "Coins"}.

To say vehicnoun:

let Z be "";

if vehicsize is 0 begin;

say "[one of][pop bikenouns][or][pop bikenouns][or][pop vnouns][or][pop fastnouns][purely at random]";

otherwise if vehicsize > 2;

say "[one of][pop vnouns][or][pop rignouns][purely at random]";

otherwise;

say "[one of][pop vnouns][or][pop fastnouns][purely at random]";

end if;

To say anycar:

now vehicsize is a random number between 0 and 3;

say "[pop vehiclenames]";

hardcoreprefs is a list of text that varies. hardcoreprefs is {"Abbatoir", "Armageddeon", "Assault", "Attack", "Babylon", "Bad", "Barbecue", "Bang", "Barrage", "Bastard", "Bastard", "Battle", "Blade", "Big Beautiful", "Bitch", "Blaze", "Blood", "Bomb", "Bone", "Boom", "Bullet", "Burn", "Butcher", "Cannibal", "Carnage", "Chaos", "Crazy", "Damnation", "Danger", "Dark", "Death", "Devil", "Demon", "Deviant", "Diesel", "Doom", "Dynamite", "Electric", "Fire", "Flame", "Flaming", "Gas", "Gun", "Graveyard", "Greased", "Grind", "Hazard", "Heavy", "Hell", "Hammer", "Infernal", "Inferno", "Iron", "Juice", "Kill", "Little", "Lunatic", "Mad", "Massacre", "Mean", "Metal", "Mud", "Muscle", "Night", "Nitro", "Obliteration", "Oblivion", "Obscene", "Panic", "Pain", "Party", "Peelout", "Perdition", "Power", "Psycho", "Rage", "Rattle", "Razor", "Red", "Redline", "Rifle", "Road", "Roadkill", "Riot", "Rude", "Rumble", "Rust", "Savage", "Sharp", "Skull", "Slaughter", "Speed", "Stab", "Steel", "Storm", "Suicide", "Tempest", "Terror", "Thorn", "Thrash", "Throttle", "Thunder", "Trouble", "Twisted", "Unholy", "War", "Wicked", "Wild", "Witch", "Wub", "[pop commonadjs]", "[pop commonnouns]", "[pop shortends]", "[pop commonverbers]", "[pop battlenames]"}.

bikenouns is a list of texts that varies. bikenouns is {"Bird", "Charger", "Cloud", "Destrier", "Hog", "Horse", "Hussar", "Mare", "Rat", "Rider", "Rocket", "Shrieker", "Stallion", "Steed", "Valkyrie", "Wind"}.

fastnouns is a list of texts that varies. fastnouns is {"Blazer", "Boy", "Courier", "Comet", "Cruiser", "Deuce", "Express", "Flyer", "Freak", "Girl", "Howler", "Interceptor", "Knight", "Lady", "Lance", "Lightning", "Missile", "Out[one of]runner[or]rider[or]pacer[purely at random]", "Racer", "Sleeper","Streak", "Torpedo", "Whip", "Whirlwind"}.

vnouns is a list of text that varies. vnouns is {"Animal", "Beast", "Bastard", "Bitch", "Bucket", "Buggy", "Cannon", "Champion", "Chariot", "Demon", "Dog", "Engine", "Fiend", "Furnace", "Gladiator", "Gin", "Harrow", "Hearse", "Horror", "Launcher", "Machine", "Menace", "Monster", "Plow", "Raider", "Ride", "Rod", "Roller", "Sled", "Special", "Throne", "Vanguard", "Wagon", "Warrior", "Wheel", "Wreck", "Terror", "[pop commonverbers]", "[pop Beasts]", "[pop Rulers]"}.

rignouns is a list of texts that varies. rignouns is {"Barge", "Battleship", "Bus", "Carrier", "Cart", "Giant", "Jugger", "Panzer", "Platform", "Rig", "Tanker", "Tank", "Tractor", "Train", "Truck"}.

carspeed is a number that varies. carspeed is 0.

cararmor is a number that varies. cararmor is 0.

carhandle is a number that varies. carhandle is 0.

temp-b is a number that varies.

To say exceptionalrig:

[now vehicsize is 0;]

now carspeed is 0;

now cararmor is 0;

now carhandle is 0;

let N be 0;

let VM be a list of texts;

say battlecar;

[convert vehicsize to the actual AW size]

if vehicsize is 5 begin;

now vehicsize is a random number between 0 and 3;

otherwise;

now vehicsize is vehicsize - 2;

end if;

let Z be a random number between -1 and 1;

now vehicsize is vehicsize + Z;

now Z is a random number between -1 and 1;

now vehicsize is vehicsize + Z;

if vehicsize < 0, now vehicsize is 0;

if vehicsize > 4, now vehicsize is 4;

now N is vehicsize;

battleoption;

if N > 0, battleoption;

if N is 0 and a random chance of 1 in 2 succeeds, now carspeed is carspeed + 1;

[say " [b]size: [vehicsize] speed: [carspeed] armor: [cararmor] handle: [carhandle] ";]

if carspeed is 1, add "fast" to VM;

if carspeed is 2, add "supercharged" to VM;

if vehicsize - N is 2, add "[one of]colossal[or]gigantic[purely at random]" to VM;

if vehicsize - N is 1, add "[one of]oversized[or]big[or]huge[purely at random]" to VM;

if cararmor is 1, add "[one of]armored[or]hardened[purely at random]" to VM;

if cararmor is 2, add "heavily armored" to VM;

if carhandle is 1, add "[one of]agile[or]manouverable[purely at random]" to VM;

if carhandle is 2, add "highly agile" to VM;

say "[b][pop vehiclenames][/b], a [VM] ";

now temp-b is N;

if N is 0, say "[one of]motorcycle[purely at random], ";

if N is 1, say "[one of]buggy[or]compact car[or]trike[purely at random], ";

if N is 2, say "[one of]coupe[or]sedan[or]jeep[or]pickup[or]van[or]limo[or]4x4[or]tractor[purely at random], ";

if N is 3, say "[one of]semi[or]bus[or]bulldozer[or]fire engine[or]dump truck[or]RV[purely at random], ";

if N is 4, say "[one of]mining truck[or]battle platform[or]land carrier[purely at random], ";

say "[noreppop rigaesth][one of] and [noreppop rigaesth][or][purely at random]. [pop rigissues][one of]. [pop rigbonuses][or]. [ridebonus N][or][purely at random].";

To say ridebonus (N - a number):

if N is 0 begin;

say "[one of]It's equipped with stunt-pegs and handles for wild-ass stunts[or]It's built for jumps, lightweight and with serious suspension[or]It's a recumbent[purely at random]";

otherwise if N is 1;

say "[one of]It's got oversized tires for scrambling through sand, mud or boulders[or]It's a half-track[purely at random]";

otherwise if N is 2;

say "[one of]It's a half-track[purely at random]";

otherwise if N is 3;

say "[one of]It's mounted with a backhoe arm[or]It rides with tow gear, enabling it to haul disabled vehicles (or make off with stolen ones)[or]It runs on tank tracks[purely at random]";

otherwise;

say "[one of]It houses a small swarm of light vehicles, bringing them in for protection, refueling and repair[or]It's armed with a wrecking-ball on a small crane[purely at random]";

end if;

To say mount (N - a number):

if N is 0 begin;

say "[one of]on a pillion mount[or]mounted on a sidecar[purely at random]";

otherwise if N is 1 or N is 2;

say "[one of]mounted in the back[or]in a passenger-seat mount[purely at random]";

otherwise;

say "[one of]mounted in a rear-facing turret[or]mounted in a forward turret[or]mounted in a side blister[or]mounted on an elevated crane[purely at random]";

end if;

rigaesth is a list of texts that varies. rigaesth is {

"painted[one of][or][or] in gorgeous[or] chaotically[or] inexpertly in[or] in stylish[purely at random] [one of]jet black[or]matte black[or]midnight black[or]blood red[or]cherry red[or]slime green[or]neon pink cammo[or]hot pink[or]in camouflage colors[or]shit brown[or]eyegrab orange[or]in a riot of vivid colors[or]in the gang colors[or]with a[*a][downpop beasts] motif[purely at random]",

"hung with [one of]enemy skulls[or]battle trophies[or]cargo netting[or]amulets, charms and religious symbols[purely at random]",

"[one of]painted[or]inscribed[or]daubed[or]covered[purely at random] with [one of]war slogans[or]flames[or]kill counts[or]ad-hoc graffiti[or]masterful graffiti[or]gang sigils[or]religious invocations[purely at random]",

"[one of]encrusted with rust and mud[or]maintained in gleaming-clean condition[or]battered and dented[purely at random]",

"[one of]muscular[or]powerful[or]grunty[purely at random]",

"[one of]sleek-lined[or]streamlined[or]stylishly streamlined, all bulges and curves[or]shark-streamlined[or]streamlined like some kind of alien fish[purely at random]",

"[one of]handcrafted[or]cobbled-together[or]in original condition[purely at random]",

"[one of]bristling with spikes[or]completely encrusted in spikes and blades[purely at random]",

"[one of]cut-down, with shell, fairings and extras removed as much as possible[or]shaped around a massive roll-cage[purely at random]",

"[one of]jacked up[or]high-riding[or]with unusually high clearance[or]with unusually low clearance[or]cut down low[or]low-riding[purely at random]"

}

rigissues is a list of texts that varies. rigissues is {

"[one of]It runs near-silent at low speeds[or]It runs smooth and quiet[or]It makes a huge racket wherever it goes[or]You can hear its engine miles off[purely at random]",

"[one of]It's hard to start up[or]Once the engine gets cool, it's a devil to start back up[or]It's hard to start it on cold mornings[or]It tends to flood on startup[or]It starts smooth and easy every time[purely at random]",

"[one of]It's an off-roader, designed for broken ground[or]It copes badly with broken ground and rough roads[purely at random]",

"[one of]It's built to simple specs using commonly-available, interchangeable parts, and is easy to repair[or]Built to exacting specs and with lots of rare and custom parts, it's a fucker to repair[or]It's a rat rig, a cluster of mismatched parts; likely to go wrong a lot, but easy to fix[purely at random]",

"[one of]It's capacious, with lots of extra room for cargo and crew[or]It's cramped, with no spare room whatsoever[purely at random]",

"[one of]Its engine belches thick smoke and choking fumes[or]Its engine runs extremely clean[or]It occasionally catches on fire for no very clear reason[purely at random]"

}

rigbonuses is a list of texts that varies. rigbonuses is {

"It's readily camouflaged, blending perfectly into the landscape when immobile",

"Machine-guns are fixed along its chassis, aimed straight ahead",

"It has a grenade launcher [mount temp-b]",

"It has a 50-cal machinegun [mount temp-b]",

"It has a flame-thrower [mount temp-b]",

"It's rigged with a [one of]mounted boarding platform[or]boarding harness[purely at random]",

"It has a[one of] forward[or] side[or] rear[or]n elevated[purely at random] mount for a [one of]sniper[or]harpooner[or]grenadier[or]gunner[or]lancer[or]flamer[or]grapple line[purely at random]",

"It's armed with [one of]a ram[or]ramming spikes[or]a cow-catcher[or]a plow blade[or]oversize bull-bars[or]wheel-scythes[purely at random]",

"It's mine-proofed."

}

To battleoption:

let N be a random number between 1 and 4;

if N is 1, now carspeed is carspeed + 1;

if N is 2, now cararmor is cararmor + 1;

if N is 3, now carhandle is carhandle + 1;

if N is 4, now vehicsize is vehicsize + 1;

carlooks is a list of texts that varies. carlooks is {"flashy", "garish", "handcrafted", "hardworked", "luxe", "muscular", "powerful", "pretty", "[one of]pristine[or]cobbled-together[purely at random]", "quirky", "sleek", "spiked", "vintage"}.

[

By default, your vehicle has speed=0, handling=0, 0-armor, and

the massive rating of its frame.

Choose its frame:

• Bike (massive=0, 1 battle option)

• Compact, buggy (massive=1, 2 battle options)

• Coupe, sedan, jeep, pickup, van, limo, 4x4, farm tractor

(massive=2, 2 battle options)

• Semi, bus, ambulance, construction/utility (massive=3, 2 battle

options)

Strengths (choose 1 or 2): Fast, rugged, aggressive, tight, huge,

off-road, responsive, uncomplaining, capacious, workhorse,

easily repaired.

Looks (choose 1 or 2): Sleek, vintage, pristine, powerful, luxe,

flashy, muscular, quirky, pretty, handcrafted, spikes & plates,

garish, cobbled-together, hardworked.

Weakness (choose 1 or 2): Slow, loud, lazy, sloppy, cramped,

picky, guzzler, unreliable, rabbity, temperamental.

Battle options (choose according to frame): +1speed, +1handling,

+1massive, +1armor. You can double up if you choose.

Creating a specialized battle vehicle:

The driver has a move, my other car is a tank, which gives her a

specialized battle vehicle. Create the vehicle as normal, and then

choose 2:

• +1 battle option (+1speed, +1handling, +1massive, or +1armor)

• Mounted machine guns (3-harm close/far area messy)

• Mounted grenade launcher (4-harm close area messy)

• Ram or ramming spikes (as a weapon, vehicle in�icts +1harm)

• Mounted 50cal mg (5-harm far area messy)

• Mounted boarding platform or harness (+1 to attempts to board

another vehicle from this one)

]