IFDB Spelunking 2 — 10 of 18

Book 3 - The Games

Part 0 - Game-Management Tools

A game is a kind of container. A game is usually scenery. A game is usually openable and closed. A game can be played or unplayed. A game is usually unplayed.

A game has some text called precis.

A game has a room called saferoom.

A game can be entitled or unentitled. A game is usually entitled.

Rule for printing the name of a room when the current game is unentitled: do nothing.

nongame is an unentitled game.

The current game is a game that varies. The current game is nongame.

Instead of entering a game (called foo): try opening foo.

Before opening a game (called foo):

now the current game is foo;

After opening a game (called foo):

now foo is closed;

now foo is played;

do nothing.

After looking in startroom:

repeat with N running through games in startroom begin;

say the precis of N;

say "[p]";

end repeat;

Concluding something is an activity on objects.

Rule for concluding a game (called foo): follow the conclusory rule.

This is the conclusory rule:

remove the current game from play;

now every thing enclosed by the player is safe;

now the current game is nongame;

now the story viewpoint is second person;

now the player is in startroom;

if there are no games in startroom, carry out the endgame;

The player carries a safety line. The description of the safety line is "For every labyrinth a thread. This line, slender and inobtrusive, has got you out of some unpleasant situations before, when maps and compasses and heavier gear failed. A sharp pull on it should trigger the auto-ascender on the far end, allowing you to cheat death or gank inventory from games even if you can't finish them."

The hisp of safety line is "línea de seguridad[note 152]". Understand "linea" or "seguridad" or "linea de seguridad" or "cord" or "rope" as safety line.

Instead of dropping safety line: say "It's not much of a safety line if you abandon it."

Instead of putting safety line on something: try dropping safety line.

Instead of inserting safety line into something: try dropping safety line.

Escaping something is an activity on objects.

Rule for escaping a game: follow the escapology rule.

This is the escapology rule:

let X be the list of unsafe things carried by the player;

if the number of entries in X > 0, say "[br][co]You are forced to abandon [X with definite articles][first time]. You can always come back for it, though[only].[/co]";

wait for any key;

repeat with Q running through X begin;

move Q to the saferoom of the current game;

if Q is strong horse, now strong horse is not ridden;

end repeat;

now the current game is played;

now the current game is nongame;

now the story viewpoint is second person;

now the player is in startroom;

if the player does not wear an outfit, now the player wears caving gear.

Retreating something is an activity on objects.

Rule for retreating a game: follow the retreatage rule.

This is the retreatage rule:

now the current game is played;

now the current game is nongame;

now the story viewpoint is second person;

now every thing enclosed by the player is safe;

now the player is in startroom;

Instead of pulling the safety line:

say "[one of]Time to go[or]Yeah, enough of this[or]Bored now[or]You don't have time to dick around in this kind of game[or]Enh[or]Your interest has flagged[as decreasingly likely outcomes]. A sharp tug on the line triggers the auto-ascender, and you are hauled back to safety.";

carry out the retreating activity with the current game;

Instead of pulling the safety line when the current game is nongame:

say "You don't intend to leave this section of the tunnels until you've either completed or dismissed all of the games.";