Invisible Parties — 11 of 31

Sam Kabo Ashwell

Release 3

Book - The Beloved

Jave is a woman. Understand "kambei" as Jave.

Instead of doing something to Jave:

if the location is an unchallenging party and the current action is not examining begin;

say "[one of]'Jave! Fuck, I'm glad you're here - wasn't sure you really were. Look, this place is a tangle, a place woven from bits of the ways and worlds. Super unstable, but I've seen some exits -'[p]She hasn't reacted at all. You're in her line of sight, she'd have to be deaf and blind to miss you. Something's up.[p]Then she jumps up, beaming, and runs with arms outstretched in a direction about forty-five degrees away from you. She fades as she moves, until she's quite gone. Shit[or]'Hey. Jave. Can you hear me, or are you - '[p]Evidently not. This time she spaces out on you for several minutes of gesticulating and yelling, and then calmly walks away, brushing you with her elbow as she goes[or]Again you try to contact Jave, and again she fails to register you, sees something else, moves to chase or follow it, and disappears[stopping].";

make the lady run;

say weaveloss;

otherwise;

continue the action;

end if;

After going from a challenging room:

if Jave is in the room gone from, make the lady run;

continue the action;

Instead of talking to Jave in an egress:

say "[one of]'Are you OK?'[p]'Yeh. Little shocky. I'll be fine.'[p]'We're still in range of the tangle, I think - keep moving?'[p]'Sure[or]'Still with me?'[p]'Yeah[stopping].'";

Instead of kissing Jave in an egress: say "You draw her in close; she dips her head down and holds you and you kiss. You're too drained to get all that turned on, at this point, but you feel immeasurably reassured.".

Instead of examining Jave when the location is an egress:

say "[the description of Jave] She's red-cheeked from sprinting, and she's grinning like a gold medalist."

Instead of touching Jave: try kissing Jave.

Instead of kissing Jave in a party: try talking to Jave.

Instead of doing something to Jave when puzzlecount is 4 and the location is not an egress:

say "Later, maybe, once you're in the clear."

Instead of talking to Jave in a challenging party:

say "[one of]You start, and... it's not that you can't make sounds, or articulate your mouth. It's not even that you can't form thoughts into words. But the process that connects the two parts doesn't work - what comes out is a garble, uninflected even by emotion. Jave attends closely, but without comprehension[or]You learned some basic operational sign-language from her in the Lacmore Slope, and you can still remember parts of it, but it's not exactly a language designed for emotional nuance. Or anything much beyond commands, really. [p][i]Acknowledge?[/i][br][i]Acknowledge.[br]Area is dangerous but no imminent threat.[br]Acknowledge.[/i] (There is no sign for 'well obviously,' or even 'yes, I know.')[br][i]Regroup.[br]Negative. Impassable terrain.[br]Hold position.[br]Negative. Area is dangerous but no imminent threat.[/i][p]Not the reunion conversation you had in mind, but it makes you feel better anyway[or]You can't really get anything across that'll [i]help[/i], and the conversation you want to have will have to wait until you're both out of here[stopping].";

say weavewin;

Rule for writing a paragraph about Jave when second-destruction is true and puzzlecount < 4:

say "You catch sight of [Jave], running as fast as she can. You can't tell to where.";

Jave wears Jave's clothes.

Understand "jumpsuit" or "vault" or "dweller" as Jave's clothes when the location is startroom.

Understand "skirt" or "updo" or "herringbone" or "glasses" as Jave's clothes when the location is office party.

Understand "heels" as Jave's clothes when the location is beautiful people.

Understand "dreads" or "dreadlocks" as Jave's clothes when the location is Under My Roof.

Understand "wedding dress" or "dress" or "veil" as Jave's clothes when the location is wedding.

Understand "weeds" or "widow's weeds" or "veil" or "handbag" as Jave's clothes when the location is wakeroom.

Understand "tank-top" or "tank top" or "top" or "tank" or "skirt" or "sandals" or "wraparound" or "wrap-around" or "cap" or "military cap" or "army cap" as Jave's clothes when the location is hotrock.

Understand "dress" or "peasant dress" as Jave's clothes when the location is maying.

Understand "bedsheet" or "sheet" or "bed" or "armlet" or "anklet" or "tiara" or "goblet" as Jave's clothes when the location is meadhall.

Understand "dress" or "art" or "deco" or "cocktail dress" as Jave's clothes when the location is doubletwisted.

Understand "dress" or "white" or "clingy" as Jave's clothes when the location is doubletwisted.

Instead of examining Jave's clothes: try examining Jave.

Instead of taking off Jave's clothes: say "You'd rather do so while not under observation."

Instead of attacking Jave: say "You have sparred a little in the past. But she's the last person you'd ever actually [i]attack[/i]."

Instead of attacking Jave when the location is wakeroom and wakeroom is not doomed: try using warrior.